From 8eb36a2b035e9d193e05f9dbc8f492dedd30745e Mon Sep 17 00:00:00 2001
From: Viorel Munteanu <ceamac@gentoo.org>
Date: Fri, 23 Feb 2024 15:01:20 +0200
Subject: app-misc/fastfetch: add 2.8.5

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
---
 app-misc/fastfetch/Manifest               |   1 +
 app-misc/fastfetch/fastfetch-2.8.5.ebuild | 115 ++++++++++++++++++++++++++++++
 2 files changed, 116 insertions(+)
 create mode 100644 app-misc/fastfetch/fastfetch-2.8.5.ebuild

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 8e0e869d8029..0b49147e52eb 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,4 @@
 DIST fastfetch-2.2.3.tar.gz 901203 BLAKE2B d6d097b72ce2f252e42b3e59cbd26b43a4f17ae974382f986270fbf91b457cf3c49e78a3c775e713d9302d536fb5a363e809005b9174d1a27622e6b6ed666709 SHA512 81e051b7555d56415c723606c0b6dfc3ad7ed91fb2c7b36c07465f4dfbdb91da5c8d216e46df36863888448de0a7bd63e28c6aa701995bf1165e0d7c33c4f724
 DIST fastfetch-2.7.1.tar.gz 1000565 BLAKE2B 061d2175bdca879bb4ef1a2f29fd73b99a7325fb8de66f05eb1203008c34ef20ff122e57a785ee0a5abb0251004023958abb1d158bc49cd1b34f9e02f3d1c6bc SHA512 55d897af532141d429aa5b58ab1516347f14597bf249b70f0d5ab27d11e235911858143fc32356255bef201cb44cdd7698e8d49094fb7e61c2e425a6c8ac5fa1
 DIST fastfetch-2.8.4.tar.gz 1010662 BLAKE2B 2f93d4a405bd06a69b510413fcdab9fa08ced7e95cd507ac82e16baf9e31a3af42efe9f8252aad7229b9a8ae4ce244a1a7f447b8b05e08970291435e8b7bce77 SHA512 ba7d55d7bcf121d0b94e1e7fe03f639dce8286c1b587bedd17363c8e4682443bf8dcd1bf64842caf8b711b41dbc262e2c3c7f9d121a5ceeedffb3f0762597c82
+DIST fastfetch-2.8.5.tar.gz 1010575 BLAKE2B 4e300bfb0361c7ab73b5a3853c2c484e1027b0eaf683f707e427d4831b8815a1c8f689be0ddf3815d31906f2260229a80b6abf41c712ac897cdcd713ab25f82a SHA512 411351ec4c600d59f06269b584a1bfb4975e8046dbb06952dd8a5cbb39c7daedb641a9518b031dd0cdd3e200a4d33e01e1f33523fd657deaa5d53b92b7a5384c
diff --git a/app-misc/fastfetch/fastfetch-2.8.5.ebuild b/app-misc/fastfetch/fastfetch-2.8.5.ebuild
new file mode 100644
index 000000000000..7fd4e9284eb7
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.8.5.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.8.0:=
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}
-- 
cgit v1.2.3-65-gdbad