From 8f4be1c606ece8a6e169c0cd87efe91de2bb36fb Mon Sep 17 00:00:00 2001
From: Michael Palimaka <kensington@gentoo.org>
Date: Sat, 17 Nov 2018 18:09:17 +1100
Subject: dev-games/tiled: version bump 1.2.1

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Michael Palimaka <kensington@gentoo.org>
---
 dev-games/tiled/Manifest           |  1 +
 dev-games/tiled/tiled-1.2.1.ebuild | 63 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+)
 create mode 100644 dev-games/tiled/tiled-1.2.1.ebuild

diff --git a/dev-games/tiled/Manifest b/dev-games/tiled/Manifest
index 3fd7b7fa6bde..8504656af23f 100644
--- a/dev-games/tiled/Manifest
+++ b/dev-games/tiled/Manifest
@@ -1 +1,2 @@
 DIST tiled-1.2.0.tar.gz 17007687 BLAKE2B 6bb5a34a19868574801a69015f6a05b299dd5b34df865cacf5d2a747a62ae731b80778fe49a432c5487cbfa3d30186dc80011cc8882cb86ac347fb35a7421cbc SHA512 9c0c151348a90344b355e9bc8a7c9d38e2203d48474e8cf496e2c08cc75f764042e4355db2827f0e3518a1c03bfbcc79be7ba643c44c50430c7ecec09fbb8563
+DIST tiled-1.2.1.tar.gz 16773680 BLAKE2B 1b7c662863d931dadd46d20c90822659b71fe5c7432cc6486813a6db533057d9db9768c2d14832a74b0f768c29b3d340cdc28a67df830ca984ad824610afe662 SHA512 9a66d41ed991b6af226c9456758f27bf5cf2e8d1059042fb684b003608509c0d0e13776710e777bab0e12f55223e4fca4048a07661c36a3273f9c6c5cbf7fa5d
diff --git a/dev-games/tiled/tiled-1.2.1.ebuild b/dev-games/tiled/tiled-1.2.1.ebuild
new file mode 100644
index 000000000000..fb9cfdad6b97
--- /dev/null
+++ b/dev-games/tiled/tiled-1.2.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_6 )
+inherit gnome2-utils multilib python-single-r1 qmake-utils xdg
+
+DESCRIPTION="A general purpose tile map editor"
+HOMEPAGE="https://www.mapeditor.org/"
+SRC_URI="https://github.com/bjorn/tiled/archive/v${PV}/${P}.tar.gz"
+
+LICENSE="BSD BSD-2 GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.9:5
+	>=dev-qt/qtgui-5.9:5
+	>=dev-qt/qtnetwork-5.9:5
+	>=dev-qt/qtwidgets-5.9:5
+	sys-libs/zlib
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS COPYING NEWS.md README.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	eqmake5 LIBDIR="/usr/$(get_libdir)" PREFIX="/usr" DISABLE_PYTHON_PLUGIN="$(usex !python)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3-65-gdbad