From 98e1ae8d190da19e52676156d08596551a5603bd Mon Sep 17 00:00:00 2001
From: Sergei Trofimovich <slyfox@gentoo.org>
Date: Fri, 30 Oct 2020 23:18:43 +0000
Subject: dev-util/rr: bump up to 5.4.0

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>
---
 dev-util/rr/Manifest        |  1 +
 dev-util/rr/rr-5.4.0.ebuild | 68 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 dev-util/rr/rr-5.4.0.ebuild

diff --git a/dev-util/rr/Manifest b/dev-util/rr/Manifest
index 7d7681e7438d..e4a3bb12f97d 100644
--- a/dev-util/rr/Manifest
+++ b/dev-util/rr/Manifest
@@ -1 +1,2 @@
 DIST mozilla-rr-5.3.0.tar.gz 1343557 BLAKE2B 80ed2feb52fd34b424193902c02408443e5ae943a34d3fe8e75c4c813042c6dd7f39571924ce94aca558ea5f1630f9bda28bea9d5f7e2d429d772a85d3e3e7ad SHA512 6ae37a3ced0c001208fb981abc18f02b912a2851564955dd8da364cb30d9580ea6c91bedbef6495da5d082954d4f261eeaea81df1e9895b4adf948e9998f4c2b
+DIST mozilla-rr-5.4.0.tar.gz 1434820 BLAKE2B 8454304fa2ddf85fcd385d3d4e72b8963dc0f6804bf572db31654cdf5bfc8a3afd050380fe34d280264114467e9b973866384d75d6f8b7078affd51064e9f597 SHA512 69b029a29cf3c147f033ff4c1c67c6190f5163b4f7329306e5f0ccfe78cae4b6ae262602253772e83d5a55408c5a4d121e5a9b3530779de74adc34b81e2592c8
diff --git a/dev-util/rr/rr-5.4.0.ebuild b/dev-util/rr/rr-5.4.0.ebuild
new file mode 100644
index 000000000000..e46b29249fe7
--- /dev/null
+++ b/dev-util/rr/rr-5.4.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+CMAKE_BUILD_TYPE=Release
+
+inherit cmake linux-info python-single-r1
+
+DESCRIPTION="Record and Replay Framework"
+HOMEPAGE="https://rr-project.org/"
+SRC_URI="https://github.com/mozilla/${PN}/archive/${PV}.tar.gz -> mozilla-${P}.tar.gz"
+
+LICENSE="MIT BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="multilib test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	sys-libs/zlib:=
+	dev-libs/capnproto:=
+	${PYTHON_DEPS}"
+RDEPEND="${DEPEND}
+	sys-devel/gdb[xml]"
+# Add all the deps needed only at build/test time.
+DEPEND+="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pexpect[${PYTHON_MULTI_USEDEP}]
+		')
+		sys-devel/gdb[xml]
+	)"
+
+RESTRICT="test" # toolchain and kernel version dependent
+
+pkg_setup() {
+	if use kernel_linux; then
+		CONFIG_CHECK="SECCOMP"
+		linux-info_pkg_setup
+	fi
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -i 's:-Werror::' CMakeLists.txt || die #609192
+}
+
+src_test() {
+	if has usersandbox ${FEATURES} ; then
+		ewarn "Test suite fails under FEATURES=usersandbox (bug #632394). Skipping."
+		return 0
+	fi
+
+	cmake_src_test
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+		-Ddisable32bit=$(usex !multilib) #636786
+	)
+
+	cmake_src_configure
+}
-- 
cgit v1.2.3-65-gdbad