From 9909bceaafa55cd574d17d1f4c7395afcc3e85c6 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Mon, 26 Dec 2022 16:59:14 +0100
Subject: sci-mathematics/frobby: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 sci-mathematics/frobby/frobby-0.9.0-r3.ebuild | 63 ---------------------------
 sci-mathematics/frobby/frobby-0.9.0-r4.ebuild | 59 +++++++++++++++++++++++++
 2 files changed, 59 insertions(+), 63 deletions(-)
 delete mode 100644 sci-mathematics/frobby/frobby-0.9.0-r3.ebuild
 create mode 100644 sci-mathematics/frobby/frobby-0.9.0-r4.ebuild

diff --git a/sci-mathematics/frobby/frobby-0.9.0-r3.ebuild b/sci-mathematics/frobby/frobby-0.9.0-r3.ebuild
deleted file mode 100644
index ae7086641b0d..000000000000
--- a/sci-mathematics/frobby/frobby-0.9.0-r3.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit toolchain-funcs
-
-DESCRIPTION="Software system and project for computations with monomial ideals"
-HOMEPAGE="http://www.broune.com/frobby/"
-SRC_URI="http://www.broune.com/frobby/frobby_v${PV}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~arm x86"
-IUSE="doc static-libs"
-
-RDEPEND="dev-libs/gmp:0=[cxx(+)]"
-DEPEND="${RDEPEND}
-	doc? ( virtual/latex-base )"
-
-S="${WORKDIR}/frobby_v${PV}"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-cflags-no-strip-soname.patch"
-	"${FILESDIR}/${PN}-gcc-4.7.patch"
-	"${FILESDIR}/${PN}-gmp-5.1.patch"
-)
-
-src_prepare() {
-	default
-
-	# CXXFLAGS are called CPPFLAGS
-	sed "s/CPPFLAGS/CXXFLAGS/" -i Makefile || die
-}
-
-src_configure() {
-	default
-	# Makefile uses the value of CXX which may be defined in /etc/env,
-	# breaking cross-compile.
-	tc-export CXX
-}
-
-src_compile() {
-	emake
-	MODE=shared emake library
-	use static-libs && emake library
-	use doc && emake docPdf
-}
-
-src_install() {
-	dobin bin/frobby
-	dolib.so bin/libfrobby.so
-	dosym libfrobby.so "${PREFIX}/usr/$(get_libdir)/libfrobby.so.0"
-	use static-libs && dolib.a bin/libfrobby.a
-
-	insinto /usr/include
-	doins src/frobby.h
-
-	insinto /usr/include/"${PN}"
-	doins src/stdinc.h
-
-	use doc && dodoc bin/manual.pdf
-}
diff --git a/sci-mathematics/frobby/frobby-0.9.0-r4.ebuild b/sci-mathematics/frobby/frobby-0.9.0-r4.ebuild
new file mode 100644
index 000000000000..14a17f5470f5
--- /dev/null
+++ b/sci-mathematics/frobby/frobby-0.9.0-r4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Software system and project for computations with monomial ideals"
+HOMEPAGE="http://www.broune.com/frobby/"
+SRC_URI="http://www.broune.com/frobby/frobby_v${PV}.tar.gz"
+S="${WORKDIR}/frobby_v${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86"
+IUSE="doc"
+
+RDEPEND="dev-libs/gmp:0=[cxx(+)]"
+DEPEND="${RDEPEND}"
+BDEPEND="doc? ( virtual/latex-base )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-cflags-no-strip-soname.patch
+	"${FILESDIR}"/${PN}-gcc-4.7.patch
+	"${FILESDIR}"/${PN}-gmp-5.1.patch
+)
+
+src_prepare() {
+	default
+
+	# CXXFLAGS are called CPPFLAGS
+	sed "s/CPPFLAGS/CXXFLAGS/" -i Makefile || die
+}
+
+src_configure() {
+	default
+	# Makefile uses the value of CXX which may be defined in /etc/env,
+	# breaking cross-compile.
+	tc-export CXX
+}
+
+src_compile() {
+	emake MODE=shared
+	emake MODE=shared library
+	use doc && emake docPdf
+}
+
+src_install() {
+	dobin bin/frobby
+	dolib.so bin/libfrobby.so
+	dosym libfrobby.so /usr/$(get_libdir)/libfrobby.so.0
+
+	doheader src/frobby.h
+
+	insinto /usr/include/frobby
+	doins src/stdinc.h
+
+	use doc && dodoc bin/manual.pdf
+}
-- 
cgit v1.2.3-65-gdbad