From 9a72d9657d8e7680240fe15716d3065d0ba3ea6b Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 1 Mar 2023 12:22:55 +0100
Subject: kde-apps/k3b: 22.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/k3b/Manifest           |   1 +
 kde-apps/k3b/k3b-22.12.3.ebuild | 108 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)
 create mode 100644 kde-apps/k3b/k3b-22.12.3.ebuild

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index e156d6f2e2af..a50be4118217 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,2 +1,3 @@
 DIST k3b-22.08.3.tar.xz 10764540 BLAKE2B 8168fa4188151f421c0c5fe1254ccabf7243e6b8afcce17bc5bcf07badf28ee51f714fd0fdfaf5d16745960c637f26c75644b81c1eb1db4f29dc1cd8640d8670 SHA512 cdedcd52528f907064b608f902cd1a1a66b4b909236697c1e0b12765a61a8b3b66b8bd823f61c23a3bc2a98fbb428caba2a99e6066e65f41f5131336cb3b2245
 DIST k3b-22.12.2.tar.xz 10948384 BLAKE2B 0aed67e80c204c9fa87ab7e751245308a7e5985fcecb618cb5afeb7e42e6ad92d5fe3643df0a88f0caa2a741445c15b05de2125b0924dba3399efdd5821c57da SHA512 31abb4f119495c70b05b71f3ebf0b08685ec771b081d5480ade9cf0a9f35409ae532a75b89601aa248bd15490e56b071692a834ae3edd117ac8f4fe73415e7f5
+DIST k3b-22.12.3.tar.xz 10947736 BLAKE2B 0694d190b6c7c35af5dfc4569e3029706b6fe8f12e32613725377dbff02db066e7a95f9bc1d790f3066df1d8837a76e6f690af2a0f13f20f294a1bcc04a04588 SHA512 2cefeab0a1eee989c5b43981c04bdc1285d4f9eb4a75cc8a93b0f7e599cc686ffafda4637b76e63acd6d954d7f1d764b09ae1aec73f5abcfb78bcd06cf693aa0
diff --git a/kde-apps/k3b/k3b-22.12.3.ebuild b/kde-apps/k3b/k3b-22.12.3.ebuild
new file mode 100644
index 000000000000..4f8ae6319ffd
--- /dev/null
+++ b/kde-apps/k3b/k3b-22.12.3.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.101.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/k3b/ https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="dvd ffmpeg flac mad musepack sndfile taglib vcd vorbis"
+
+REQUIRED_USE="flac? ( taglib )"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-apps/libkcddb-${PVCUT}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib?]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( >=media-libs/flac-1.2:=[cxx] )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	app-cdr/cdrtools
+	dev-libs/libburn
+	media-sound/cdparanoia
+	dvd? ( >=app-cdr/dvd+rw-tools-7 )
+	vcd? ( media-video/vcdimager )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=OFF
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=OFF
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	elog
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+}
-- 
cgit v1.2.3-65-gdbad