From 9fac09e4bd372a2682be828060c5d7752e631f03 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sat, 2 Jan 2021 06:44:21 +0000
Subject: sys-apps/miller: bump to 5.10.0

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>
---
 sys-apps/miller/Manifest             |  1 +
 sys-apps/miller/miller-5.10.0.ebuild | 48 ++++++++++++++++++++++++++++++++++++
 2 files changed, 49 insertions(+)
 create mode 100644 sys-apps/miller/miller-5.10.0.ebuild

diff --git a/sys-apps/miller/Manifest b/sys-apps/miller/Manifest
index 254099599401..5967ca148fca 100644
--- a/sys-apps/miller/Manifest
+++ b/sys-apps/miller/Manifest
@@ -1 +1,2 @@
+DIST miller-5.10.0.tar.gz 6793426 BLAKE2B 25ec96e29ee8d913feffd6e9a54cd2d494c9050e180556ed462a6d94a6adaaea88dbdbc09b4753f8888673bdc33a1f0aa43f9dac37bdc3c25191b2a565fe8847 SHA512 a7cbaee9ad4075d27e74ab3a60297164c535ea2bc1e38128174f4f226ad061850d37108e7d7547821b7e6667cb9a024639795d7678b1897fedf6ee15d6064538
 DIST miller-5.3.0.tar.gz 4940072 BLAKE2B 2e34ae010d409877040a60b08dd615f32e6945ca3bf97c078c89b9d2811067fa4bca2403f8ad239f8245e050acb10305d351b1db4177541a4fa9ed9a4bc1396c SHA512 4c557d97eb1cda2e52093fa097677602491895dea3093776a03af56114022b8c0917df9fbf26071d4d1a3c1360f520c82e33b32635c7b4207fa62869ab564712
diff --git a/sys-apps/miller/miller-5.10.0.ebuild b/sys-apps/miller/miller-5.10.0.ebuild
new file mode 100644
index 000000000000..e0e1b73a7b1a
--- /dev/null
+++ b/sys-apps/miller/miller-5.10.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="A tool like sed, awk, cut, join, and sort for name-indexed data (CSV, JSON, ..)"
+HOMEPAGE="https://johnkerl.org/miller/doc/index.html"
+SRC_URI="https://github.com/johnkerl/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND="sys-devel/flex"
+
+src_prepare() {
+	default
+
+	# respect flags
+	find -type f -name "Makefile.am" -exec sed -i -r -e '/.*FLAGS[^=]*=/ s:(-g|-pg|-O[0-9]) ::g' -- {} \; || die
+
+	# disable docs rebuilding as they're shipped prebuilt
+	sed -e '/SUBDIRS[^=]*=/ s:doc::g' -i -- Makefile.am || die
+
+	# disable building tests automagically
+	if ! use test; then
+		sed -e '/SUBDIRS[^=]*=/ s:[^ ]*_test::g' -i -- c/Makefile.am || die
+	fi
+
+	eautoreconf
+}
+
+src_test() {
+	emake -C c/reg_test
+	emake -C c/unit_test
+}
+
+src_install() {
+	local HTML_DOCS=( $(usev doc) )
+
+	default
+
+	doman 'docs/mlr.1'
+}
-- 
cgit v1.2.3-65-gdbad