From a04390dd5ba8eef929bba14f7122271b4c85c00d Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Wed, 23 Mar 2022 17:31:46 -0700
Subject: dev-util/umockdev: Version bump to 0.17.8

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-util/umockdev/Manifest               |  1 +
 dev-util/umockdev/umockdev-0.17.8.ebuild | 53 ++++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)
 create mode 100644 dev-util/umockdev/umockdev-0.17.8.ebuild

diff --git a/dev-util/umockdev/Manifest b/dev-util/umockdev/Manifest
index 1504f17fb073..eb580a622d7e 100644
--- a/dev-util/umockdev/Manifest
+++ b/dev-util/umockdev/Manifest
@@ -1,2 +1,3 @@
 DIST umockdev-0.17.6.tar.xz 486668 BLAKE2B 973c195b8fccd1c080665b65ffd47f8fe110118de9c541d5dda383e51e4dbcc36f77eeda6af5c774f4570a7b839190130fe95559fb3148e9937dae19dace6331 SHA512 05a86e2a583972d02fb3cfa26b017d44600831b6ed1415769d7cc7344357f484d34228b1593de2cfbfcce302611c0c22f045ee9fbd7fea76d8ae0b4ccd28d6ef
 DIST umockdev-0.17.7.tar.xz 486964 BLAKE2B f3c4021198c8adea47383f3d0c111f921c35550ca9b70c0711e71799ba89a44031356a687b88cc80aa51b1bf4606cfcf48a1d24d16501b0ea08f805e4e30cf83 SHA512 6fc611787c9679f450ce7cdf7dccb93a5d7435470b0b5f5cb1803036cf3c8ce73521af9e7777bec68485834cddfddba0ed9379a0818bfb072bb643cf6419c17d
+DIST umockdev-0.17.8.tar.xz 487220 BLAKE2B 6a5cb31462ef5836f6a4329fe0e612dd6bb6f00ecc899cb3d1b093771727361bfbc952c7cf7acb7943b78989cacb1faa2d7a2ee62d9c752ed959ac7b1931333c SHA512 e5e6ba2934e1df9323a4e64ee1fc066ab4abeaf75ad0d7f1f6d387b06315f30877f48664e5992f4b138fe1b76d08860359599249d5b9de516777cf8bdb1b228f
diff --git a/dev-util/umockdev/umockdev-0.17.8.ebuild b/dev-util/umockdev/umockdev-0.17.8.ebuild
new file mode 100644
index 000000000000..c1f80ba0b6d7
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.17.8.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson-multilib python-any-r1 vala
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-libs/libpcap[${MULTILIB_USEDEP}]
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}
-- 
cgit v1.2.3-65-gdbad