From a46d8050905d8367c2395243b9d2ec9324a149ed Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Sun, 10 Sep 2023 21:09:37 +0300
Subject: app-admin/ccze: EAPI=8, enable tests

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 app-admin/ccze/ccze-0.2.1-r5.ebuild | 43 +++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 app-admin/ccze/ccze-0.2.1-r5.ebuild

diff --git a/app-admin/ccze/ccze-0.2.1-r5.ebuild b/app-admin/ccze/ccze-0.2.1-r5.ebuild
new file mode 100644
index 000000000000..15290385eb75
--- /dev/null
+++ b/app-admin/ccze/ccze-0.2.1-r5.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools fixheadtails toolchain-funcs
+
+DESCRIPTION="A flexible and fast logfile colorizer"
+HOMEPAGE="https://git.madhouse-project.org/archive/ccze"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+
+DEPEND="dev-libs/libpcre
+	sys-libs/ncurses:0="
+RDEPEND="${DEPEND}"
+
+DOCS=( AUTHORS ChangeLog ChangeLog-0.1 NEWS THANKS README FAQ )
+
+PATCHES=(
+	"${FILESDIR}"/ccze-fbsd.patch
+	"${FILESDIR}"/ccze-segfault.patch
+	"${FILESDIR}"/ccze-ldflags.patch
+	"${FILESDIR}"/${P}-tinfo.patch
+)
+
+src_prepare() {
+	default
+
+	# GCC 4.x fixes
+	sed -e 's/-Wswitch -Wmulticharacter/-Wswitch/' \
+	    -i src/Makefile.in || die
+	sed -e '/AC_CHECK_TYPE(error_t, int)/d' \
+	    -i configure.ac || die
+
+	eautoreconf
+
+	ht_fix_file Rules.mk.in
+
+	tc-export CC
+}
-- 
cgit v1.2.3-65-gdbad