From a8b45e983c4a03566e2341538f688684ea1b2c47 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 29 Dec 2018 23:46:47 +0100
Subject: sci-geosciences/merkaartor: Fix plugin path

Sync 9999 with 0.18.3-r3 changes
Drop bundled libs
Drop obsolete pkg_preinst

Thanks-to: Jonathan Marten <jjm@keelhaul.me.uk>
Closes: https://bugs.gentoo.org/621826
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../merkaartor/merkaartor-0.18.3-r4.ebuild         | 90 ++++++++++++++++++++++
 sci-geosciences/merkaartor/merkaartor-9999.ebuild  | 16 ++--
 2 files changed, 98 insertions(+), 8 deletions(-)
 create mode 100644 sci-geosciences/merkaartor/merkaartor-0.18.3-r4.ebuild

diff --git a/sci-geosciences/merkaartor/merkaartor-0.18.3-r4.ebuild b/sci-geosciences/merkaartor/merkaartor-0.18.3-r4.ebuild
new file mode 100644
index 000000000000..29f7b22e8be1
--- /dev/null
+++ b/sci-geosciences/merkaartor/merkaartor-0.18.3-r4.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PLOCALES="ar cs de en es et fr hr hu id_ID it ja nl pl pt_BR pt ru sk sv uk vi zh_CN zh_TW"
+
+inherit gnome2-utils l10n qmake-utils xdg-utils
+
+DESCRIPTION="Qt based map editor for the openstreetmap.org project"
+HOMEPAGE="http://www.merkaartor.be https://github.com/openstreetmap/merkaartor"
+SRC_URI="https://github.com/openstreetmap/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug exif gps libproxy"
+
+RDEPEND="
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsingleapplication[X,qt5(+)]
+	dev-qt/qtsvg:5
+	dev-qt/qtwebkit:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sci-libs/gdal
+	sci-libs/proj
+	sys-libs/zlib
+	exif? ( media-gfx/exiv2:= )
+	gps? ( >=sci-geosciences/gpsd-3.17-r2 )
+	libproxy? ( net-libs/libproxy )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+PATCHES=( "${FILESDIR}/${P}-sharedir-pluginsdir.patch" ) # bug 621826
+
+DOCS=( AUTHORS CHANGELOG )
+
+src_prepare() {
+	default
+
+	rm -r 3rdparty || die "Failed to remove bundled libs"
+
+	my_rm_loc() {
+		sed -i -e "s:../translations/${PN}_${1}.\(ts\|qm\)::" src/src.pro || die
+		rm "translations/${PN}_${1}.ts" || die
+	}
+
+	if [[ -n "$(l10n_get_locales)" ]]; then
+		l10n_for_each_disabled_locale_do my_rm_loc
+		$(qt5_get_bindir)/lrelease src/src.pro || die
+	fi
+
+	# build system expects to be building from git
+	sed -i "${S}"/src/Config.pri -e "s:SION = .*:SION = \"${PV}\":g" || die
+}
+
+src_configure() {
+	# TRANSDIR_SYSTEM is for bug #385671
+	eqmake5 \
+		PREFIX="${ED%/}/usr" \
+		LIBDIR="${ED%/}/usr/$(get_libdir)" \
+		PLUGINS_DIR="/usr/$(get_libdir)/${PN}/plugins" \
+		SHARE_DIR_PATH="/usr/share/${PN}" \
+		TRANSDIR_MERKAARTOR="${ED%/}/usr/share/${PN}/translations" \
+		TRANSDIR_SYSTEM="${EPREFIX}/usr/share/qt5/translations" \
+		SYSTEM_QTSA=1 \
+		RELEASE=1 \
+		NODEBUG=$(usex debug 0 1) \
+		GEOIMAGE=$(usex exif 1 0) \
+		GPSDLIB=$(usex gps 1 0) \
+		LIBPROXY=$(usex libproxy 1 0) \
+		ZBAR=0 \
+		Merkaartor.pro
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/sci-geosciences/merkaartor/merkaartor-9999.ebuild b/sci-geosciences/merkaartor/merkaartor-9999.ebuild
index fa01cf15ac09..4491ffa4a5cd 100644
--- a/sci-geosciences/merkaartor/merkaartor-9999.ebuild
+++ b/sci-geosciences/merkaartor/merkaartor-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -39,6 +39,8 @@ DEPEND="${RDEPEND}
 	virtual/pkgconfig
 "
 
+PATCHES=( "${FILESDIR}/${PN}-0.18.3-sharedir-pluginsdir.patch" ) # bug 621826
+
 DOCS=( AUTHORS CHANGELOG )
 
 src_unpack() {
@@ -67,9 +69,11 @@ src_prepare() {
 src_configure() {
 	# TRANSDIR_SYSTEM is for bug #385671
 	eqmake5 \
-		PREFIX="${ED}usr" \
-		LIBDIR="${ED}usr/$(get_libdir)" \
-		TRANSDIR_MERKAARTOR="${ED}usr/share/${PN}/translations" \
+		PREFIX="${ED%/}/usr" \
+		LIBDIR="${ED%/}/usr/$(get_libdir)" \
+		PLUGINS_DIR="/usr/$(get_libdir)/${PN}/plugins" \
+		SHARE_DIR_PATH="/usr/share/${PN}" \
+		TRANSDIR_MERKAARTOR="${ED%/}/usr/share/${PN}/translations" \
 		TRANSDIR_SYSTEM="${EPREFIX}/usr/share/qt5/translations" \
 		SYSTEM_QTSA=1 \
 		NODEBUG=$(usex debug 0 1) \
@@ -80,10 +84,6 @@ src_configure() {
 		Merkaartor.pro
 }
 
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
 pkg_postinst() {
 	xdg_desktop_database_update
 	gnome2_icon_cache_update
-- 
cgit v1.2.3-65-gdbad