From a9e3b8e119d4c1cc1a4e9c74e4c95aa32a5f797e Mon Sep 17 00:00:00 2001
From: Zac Medico <zmedico@gentoo.org>
Date: Tue, 7 Jun 2022 20:16:19 -0700
Subject: dev-util/ostree: add 2022.4

Signed-off-by: Zac Medico <zmedico@gentoo.org>
---
 dev-util/ostree/Manifest             |   1 +
 dev-util/ostree/ostree-2022.4.ebuild | 107 +++++++++++++++++++++++++++++++++++
 2 files changed, 108 insertions(+)
 create mode 100644 dev-util/ostree/ostree-2022.4.ebuild

diff --git a/dev-util/ostree/Manifest b/dev-util/ostree/Manifest
index c21b8aaf8f40..4674bbb68393 100644
--- a/dev-util/ostree/Manifest
+++ b/dev-util/ostree/Manifest
@@ -1,2 +1,3 @@
 DIST ostree-2021.3.tar.xz 2089804 BLAKE2B 5df33b676173b1ec08ac7592d4ddf8e3bfdcd84df1b3ce19e2f24c85780fed1f210b8adce1baf4ec87869c72984502276bf6e5a72268daaae6ce9b3d6dc6f88b SHA512 0df0d8f9bd82b16562dd5146997eddfb7cb6cffc1886601307d97a1cb1dc926bda7d0c899db26c974ed0dff1012dee11937e47c11c4d03307fa3d2d430adc60e
 DIST ostree-2022.2.tar.xz 2059592 BLAKE2B 73bb563be473f3f62ab2d0e1ec6e2b659c8c12aaba828ae6fd5bab4b6bd3a978ffe5d76e17734e40c0569e3e74f13b85aaf9ae467747c5bbb309c73b373e9909 SHA512 07be16101aa00f541833dc6123f015ee1af65e40e2c237322a129e944fa19791e7cad6f0b29ced3c128adbe23bdb3c8708688fadd4ed80b160acab584b84abfe
+DIST ostree-2022.4.tar.xz 2066276 BLAKE2B 67fe73babe11dac93f8e035f7baf39e98aa2be2d797d3831a30999de2f7205b33c3d0892d2ec007807f8720e15161ecccb7e5f3c047d07cb5763bfcac2170bd8 SHA512 a7745b951b1f36f483c215b311f86d860b988ebb06612e7eef2797fc34322c256ae83177337d918f3e8e3833fe9802f7d53131db59df73d29fb6c305b78879e5
diff --git a/dev-util/ostree/ostree-2022.4.ebuild b/dev-util/ostree/ostree-2022.4.ebuild
new file mode 100644
index 000000000000..43f60e37b878
--- /dev/null
+++ b/dev-util/ostree/ostree-2022.4.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="Operating system and container binary deployment and upgrades"
+HOMEPAGE="https://ostreedev.github.io/ostree/"
+SRC_URI="https://github.com/ostreedev/ostree/releases/download/v${PV}/lib${P}.tar.xz -> ${P}.tar.xz"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+LICENSE="LGPL-2+"
+SLOT="0"
+
+IUSE="archive +curl doc dracut gnutls +gpg grub +http2 httpd introspection libmount selinux sodium ssl +soup systemd zeroconf"
+RESTRICT+=" test"
+REQUIRED_USE="
+	dracut? ( systemd )
+	http2? ( curl )
+	httpd? ( || ( curl soup ) )
+"
+
+COMMON_DEPEND="
+	app-arch/xz-utils
+	dev-libs/libassuan
+	dev-libs/glib:2
+	sys-fs/fuse:3
+	sys-libs/zlib
+	archive? ( app-arch/libarchive:= )
+	curl? ( net-misc/curl )
+	dracut? ( sys-kernel/dracut )
+	gpg? (
+		app-crypt/gpgme:=
+		dev-libs/libgpg-error
+	)
+	grub? ( sys-boot/grub:2= )
+	introspection? ( dev-libs/gobject-introspection )
+	libmount? ( sys-apps/util-linux )
+	selinux? ( sys-libs/libselinux )
+	sodium? ( >=dev-libs/libsodium-1.0.14:= )
+	soup? ( net-libs/libsoup:2.4 )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? (
+			dev-libs/openssl:0=
+		)
+	)
+	systemd? ( sys-apps/systemd:0= )
+	zeroconf? ( net-dns/avahi[dbus] )"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )"
+
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	sys-devel/flex
+	sys-devel/bison
+	virtual/pkgconfig"
+
+S="${WORKDIR}/lib${P}"
+
+src_prepare() {
+	sed -Ee 's:(XSLT_STYLESHEET = ).*:\1/usr/share/sgml/docbook/xsl-stylesheets/manpages/docbook.xsl:' \
+		-i Makefile.in Makefile-man.am || die
+	eautoreconf
+	default
+}
+
+src_configure() {
+	local econfargs=(
+		--enable-man
+		--enable-shared
+		--with-grub2-mkconfig-path=grub-mkconfig
+		--with-modern-grub
+		$(use_with archive libarchive)
+		$(use_with curl)
+		$(use_with dracut dracut yesbutnoconf) #816867
+		$(use_enable doc gtk-doc)
+		$(usex introspection --enable-introspection={,} yes no)
+		$(use_with gpg gpgme)
+		$(use_enable http2)
+		$(use_enable httpd trivial-httpd-cmdline)
+		$(use_with selinux )
+		$(use_with soup)
+		$(use_with libmount)
+		$(use ssl && { use gnutls && echo --with-crypto=gnutls || echo --with-crypto=openssl; })
+		$(use_with sodium ed25519-libsodium)
+		$(use_with systemd libsystemd)
+		$(use_with zeroconf avahi)
+	)
+
+	if use systemd; then
+		econfargs+=(--with-systemdsystemunitdir="$(systemd_get_systemunitdir)")
+	fi
+
+	unset ${!XDG_*} #657346 g-ir-scanner sandbox violation
+	econf "${econfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad