From aa603dbb75d476cce89a9fb10a247f9d2910baab Mon Sep 17 00:00:00 2001
From: James Le Cuirot <chewi@gentoo.org>
Date: Tue, 26 Dec 2017 11:20:16 +0000
Subject: media-libs/libopenglrecorder: Changes following user contribution

* QA fixes
* Missing libvorbis dependency
* Don't dlopen libpulse
* Multilib
* Extra DOCS

Package-Manager: Portage-2.3.19, Repoman-2.3.6
---
 .../libopenglrecorder-0.1.0.ebuild                 | 37 ++++++++++++----------
 media-libs/libopenglrecorder/metadata.xml          | 15 +++++++++
 2 files changed, 36 insertions(+), 16 deletions(-)
 create mode 100644 media-libs/libopenglrecorder/metadata.xml

diff --git a/media-libs/libopenglrecorder/libopenglrecorder-0.1.0.ebuild b/media-libs/libopenglrecorder/libopenglrecorder-0.1.0.ebuild
index 55cfad2dd759..0c7321d83fd4 100644
--- a/media-libs/libopenglrecorder/libopenglrecorder-0.1.0.ebuild
+++ b/media-libs/libopenglrecorder/libopenglrecorder-0.1.0.ebuild
@@ -3,36 +3,41 @@
 
 EAPI=6
 
-inherit cmake-utils
+inherit cmake-multilib
 
-DESCRIPTION="A library allowing optional async readback OpenGL frame buffer with optional audio recording"
+DESCRIPTION="Library for asynchronous OpenGL recording with audio"
 HOMEPAGE="https://github.com/Benau/libopenglrecorder"
 SRC_URI="${HOMEPAGE}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE="vpx openh264 -pulseaudio"
+IUSE="openh264 sound vpx"
+
+DEPEND="media-libs/libjpeg-turbo[${MULTILIB_USEDEP}]
+	openh264? ( media-libs/openh264[${MULTILIB_USEDEP}] )
+	sound? (
+		media-libs/libvorbis[${MULTILIB_USEDEP}]
+		media-sound/pulseaudio[${MULTILIB_USEDEP}]
+	)
+	vpx? ( media-libs/libvpx:0=[${MULTILIB_USEDEP}] )"
 
-DEPEND="media-libs/libjpeg-turbo vpx? ( media-libs/libvpx ) openh264? ( media-libs/openh264 ) pulseaudio? ( media-sound/pulseaudio )"
 RDEPEND="${DEPEND}"
 
-src_prepare() {
-	cmake-utils_src_prepare
-}
+DOCS=(
+	CHANGELOG.md
+	README.md
+	USAGE.md
+)
 
-src_configure() {
+multilib_src_configure() {
 	local mycmakeargs=(
+			-DBUILD_PULSE_WO_DL=ON
 			-DBUILD_SHARED_LIBS=ON
-			-DBUILD_WITH_VPX=$(usex vpx)
+			-DSTATIC_RUNTIME_LIBS=OFF
 			-DBUILD_WITH_H264=$(usex openh264)
-			-DBUILD_RECORDER_WITH_SOUND=$(usex pulseaudio)
-			-DCMAKE_INSTALL_PREFIX=${EPREFIX}/usr
-			-DCMAKE_BUILD_TYPE=Release
+			-DBUILD_RECORDER_WITH_SOUND=$(usex sound)
+			-DBUILD_WITH_VPX=$(usex vpx)
 	)
 	cmake-utils_src_configure
 }
-
-src_install() {
-	cmake-utils_src_install
-}
diff --git a/media-libs/libopenglrecorder/metadata.xml b/media-libs/libopenglrecorder/metadata.xml
new file mode 100644
index 000000000000..a3eb35c0534e
--- /dev/null
+++ b/media-libs/libopenglrecorder/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<use>
+		<flag name="openh264">Enable H.264 support using <pkg>media-libs/openh264</pkg></flag>
+		<flag name="vpx">Enable VP8/VP9 codec support via <pkg>media-libs/libvpx</pkg></flag>
+	</use>
+	<upstream>
+		<remote-id type="github">Benau/libopenglrecorder</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad