From ab7b56b834cbeea8d3ede8435caab2108272d652 Mon Sep 17 00:00:00 2001
From: Nils Freydank <holgersson@posteo.de>
Date: Mon, 2 Mar 2020 23:24:31 +0100
Subject: dev-libs/libixion: Bump to 0.15.0

It includes some ebuild maintenance, too:
- switching from backslashes to arrays
- adding a * in front of the live ebuild numbers (*9999)

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Nils Freydank <holgersson@posteo.de>
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-libs/libixion/Manifest               |  1 +
 dev-libs/libixion/libixion-0.15.0.ebuild | 57 ++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)
 create mode 100644 dev-libs/libixion/libixion-0.15.0.ebuild

diff --git a/dev-libs/libixion/Manifest b/dev-libs/libixion/Manifest
index 285417ff8cbf..b92fc86a2fa3 100644
--- a/dev-libs/libixion/Manifest
+++ b/dev-libs/libixion/Manifest
@@ -1 +1,2 @@
 DIST libixion-0.14.1.tar.xz 360568 BLAKE2B e4da21f0eff9111272618d1bad87790ed0c4b461478473654f8366b0023c0650b41d355b0737a4fd4ac943e66f919e2f0d6bf04250e597e54a290d4415f3a093 SHA512 e4ae6348833d2178c1dc76916937bcc9d7821dc6570fe13093c441ca22e0301a1ca6a4cf85d9814b83534733dba98f4c4a372791f93bc57173317657675b9ae3
+DIST libixion-0.15.0.tar.xz 447388 BLAKE2B 55df3417783f1653b0aa4b80a5f0107a3794fcb403c1c1263ce9829b31ee5263a104fa210be151535c1ff091d5dc2519f694ef3cdb16074f86dab4d48a127afd SHA512 feecaa4a8e6191649a7ecbc6c0f4d7db6dba3a5e4a031c1f55236907bf94e2ece9ee05d18ed345e3503cffb4a380b04f6c4941ef4214ddf92687998a070b7543
diff --git a/dev-libs/libixion/libixion-0.15.0.ebuild b/dev-libs/libixion/libixion-0.15.0.ebuild
new file mode 100644
index 000000000000..741d54be08e4
--- /dev/null
+++ b/dev-libs/libixion/libixion-0.15.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-single-r1
+
+DESCRIPTION="General purpose formula parser & interpreter"
+HOMEPAGE="https://gitlab.com/ixion/ixion"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
+	inherit git-r3 autotools
+else
+	SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/0.15" # based on SONAME of libixion.so
+IUSE="debug python static-libs +threads"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-libs/boost:=
+	>=dev-util/mdds-1.5.0:1=
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}
+	dev-libs/spdlog
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable python)
+		$(use_enable static-libs static)
+		$(use_enable threads)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}
-- 
cgit v1.2.3-65-gdbad