From b191362dda3d626cb47d863c309d640befa536aa Mon Sep 17 00:00:00 2001
From: "Andreas K. Hüttel" <dilfridge@gentoo.org>
Date: Sat, 6 Jan 2018 20:37:31 +0100
Subject: dev-libs/dietlibc: Add revbump using -no-pie for gcc-6 and later, bug
 622118

Closes: https://bugs.gentoo.org/622118
Package-Manager: Portage-2.3.19, Repoman-2.3.6
---
 .../dietlibc/dietlibc-0.34_pre20140729-r1.ebuild   | 64 ++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 dev-libs/dietlibc/dietlibc-0.34_pre20140729-r1.ebuild

diff --git a/dev-libs/dietlibc/dietlibc-0.34_pre20140729-r1.ebuild b/dev-libs/dietlibc/dietlibc-0.34_pre20140729-r1.ebuild
new file mode 100644
index 000000000000..ab312bfd8734
--- /dev/null
+++ b/dev-libs/dietlibc/dietlibc-0.34_pre20140729-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="A libc optimized for small size"
+HOMEPAGE="http://www.fefe.de/dietlibc/"
+SRC_URI="https://dev.gentoo.org/~patrick/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 ~arm ~ia64 ~mips sparc x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+DEPEND=""
+RDEPEND=""
+
+DIETHOME=/usr/diet
+
+S=${WORKDIR}/dietlibc
+
+src_prepare() {
+	# Replace sparc64 related C[XX]FLAGS (see bug #45716)
+	use sparc && replace-sparc64-flags
+
+	# gcc-hppa suffers support for SSP, compilation will fail
+	use hppa && strip-unsupported-flags
+
+	# Makefile does not append CFLAGS
+	append-flags -nostdinc -W -Wall -Wextra -Wchar-subscripts \
+		-Wmissing-prototypes -Wmissing-declarations -Wno-switch \
+		-Wno-unused -Wredundant-decls -fno-strict-aliasing
+
+	# Disable ssp for we default to it on >=gcc-4.8.3
+	append-flags $(test-flags -fno-stack-protector)
+
+	# only use -nopie on archs that support it
+	tc-enables-pie && append-flags -no-pie
+
+	sed -i -e 's:strip::' Makefile || die
+	append-flags -Wa,--noexecstack
+}
+
+src_compile() {
+	emake -j1 prefix="${EPREFIX}"${DIETHOME} \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		STRIP=":"
+}
+
+src_install() {
+	emake -j1 prefix="${EPREFIX}"${DIETHOME} \
+		DESTDIR="${D}" \
+		install-bin \
+		install-headers \
+		install-profiling
+
+	dobin "${ED}"${DIETHOME}/bin/*
+	doman "${ED}"${DIETHOME}/man/*/*
+	rm -r "${ED}"${DIETHOME}/{man,bin} || die
+
+	dodoc AUTHOR BUGS CAVEAT CHANGES README THANKS TODO PORTING
+}
-- 
cgit v1.2.3-65-gdbad