From b4f8b8fae3ad4f7337ca9b8cb1a7a19a559049b2 Mon Sep 17 00:00:00 2001
From: Harri Nieminen <moikkis@gmail.com>
Date: Thu, 2 Mar 2017 11:10:01 +0200
Subject: x11-misc/xmountains: EAPI bump 4 -> 6

Package-Manager: Portage-2.3.4, Repoman-2.3.2
Closes: https://github.com/gentoo/gentoo/pull/4098
---
 x11-misc/xmountains/xmountains-2.9-r1.ebuild | 48 ++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 x11-misc/xmountains/xmountains-2.9-r1.ebuild

diff --git a/x11-misc/xmountains/xmountains-2.9-r1.ebuild b/x11-misc/xmountains/xmountains-2.9-r1.ebuild
new file mode 100644
index 000000000000..7bf5d4f892c9
--- /dev/null
+++ b/x11-misc/xmountains/xmountains-2.9-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+MY_P=${P/-/_}
+
+DESCRIPTION="Fractal terrains of snow-capped mountains near water"
+HOMEPAGE="https://spbooth.github.io/xmountains/"
+SRC_URI="http://www.epcc.ed.ac.uk/~spb/${PN}/${MY_P}.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND="
+	x11-libs/libX11
+	x11-misc/xbitmaps"
+DEPEND="${RDEPEND}
+	x11-proto/xproto"
+
+S=${WORKDIR}
+
+src_prepare() {
+	default
+	# add missing include for strcmp
+	sed -i xmountains.c -e '1a#include <string.h> /* strcmp() */' || die
+	# remove obsolete references to global.*
+	sed -i Makefile.alt README -e 's|global\..||g' || die
+}
+
+src_compile() {
+	emake \
+		-f Makefile.alt \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		${PN}
+}
+
+src_install() {
+	dobin ${PN}
+	newman ${PN}.man ${PN}.1
+	einstalldocs
+}
-- 
cgit v1.2.3-65-gdbad