From b7054239211abad0f5102843008221819e5fbdfe Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Fri, 9 Sep 2022 09:59:11 +0200
Subject: media-libs/libgii: drop multilib, EAPI 8

No multilib reverse-dependencies.

Signed-off-by: Sam James <sam@gentoo.org>
Signed-off-by: David Seifert <soap@gentoo.org>
---
 media-libs/libgii/libgii-1.0.2-r2.ebuild | 55 --------------------------------
 media-libs/libgii/libgii-1.0.2-r3.ebuild | 54 +++++++++++++++++++++++++++++++
 2 files changed, 54 insertions(+), 55 deletions(-)
 delete mode 100644 media-libs/libgii/libgii-1.0.2-r2.ebuild
 create mode 100644 media-libs/libgii/libgii-1.0.2-r3.ebuild

diff --git a/media-libs/libgii/libgii-1.0.2-r2.ebuild b/media-libs/libgii/libgii-1.0.2-r2.ebuild
deleted file mode 100644
index fa64df33f0cc..000000000000
--- a/media-libs/libgii/libgii-1.0.2-r2.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools multilib-minimal
-
-DESCRIPTION="Easy to use, but yet powerful, API for all possible input sources"
-HOMEPAGE="https://ibiblio.org/ggicore/packages/libgii.html"
-SRC_URI="mirror://sourceforge/ggi/${P}.src.tar.bz2"
-
-LICENSE="LGPL-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE="X"
-
-RDEPEND="
-	X? (
-		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
-		>=x11-libs/libXxf86dga-1.1.4[${MULTILIB_USEDEP}]
-	)"
-DEPEND="${RDEPEND}
-	kernel_linux? ( >=sys-kernel/linux-headers-2.6.11 )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.9.0-linux26-headers.patch
-	"${FILESDIR}"/${P}-configure-cpuid-pic.patch
-	"${FILESDIR}"/${P}-libtool_1.5_compat.patch
-)
-
-DOCS=( ChangeLog ChangeLog.1999 FAQ NEWS README )
-
-MULTILIB_WRAPPED_HEADERS=( /usr/include/ggi/system.h )
-
-src_prepare() {
-	default
-	rm -f acinclude.m4 m4/libtool.m4 m4/lt*.m4
-	AT_M4DIR=m4 eautoreconf
-
-	multilib_copy_sources
-}
-
-multilib_src_configure() {
-	local myeconfargs=(
-		$(use_with X x)
-		$(use_enable X x)
-		--disable-static
-	)
-	econf ${myeconfargs[@]}
-}
-
-multilib_src_install() {
-	default
-	find "${D}" -name '*.la' -delete || die
-}
diff --git a/media-libs/libgii/libgii-1.0.2-r3.ebuild b/media-libs/libgii/libgii-1.0.2-r3.ebuild
new file mode 100644
index 000000000000..1d7d2bbc8b70
--- /dev/null
+++ b/media-libs/libgii/libgii-1.0.2-r3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Easy to use, but yet powerful, API for all possible input sources"
+HOMEPAGE="https://ibiblio.org/ggicore/packages/libgii.html"
+SRC_URI="mirror://sourceforge/ggi/${P}.src.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
+IUSE="X"
+
+RDEPEND="
+	X? (
+		>=x11-libs/libX11-1.6.2
+		>=x11-libs/libXxf86dga-1.1.4
+	)"
+DEPEND="${RDEPEND}
+	kernel_linux? ( >=sys-kernel/linux-headers-2.6.11 )"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.9.0-linux26-headers.patch
+	"${FILESDIR}"/${P}-configure-cpuid-pic.patch
+	"${FILESDIR}"/${P}-libtool_1.5_compat.patch
+)
+
+src_prepare() {
+	default
+
+	rm -f acinclude.m4 m4/libtool.m4 m4/lt*.m4 || die
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with X x)
+		$(use_enable X x)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	dodoc ChangeLog.1999
+
+	find "${ED}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad