From beb4ce1d4d6adde82a808df167f78f47c87eaace Mon Sep 17 00:00:00 2001
From: Viorel Munteanu <ceamac@gentoo.org>
Date: Tue, 30 Apr 2024 17:17:36 +0300
Subject: app-misc/fastfetch: add 2.11.0

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
---
 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.11.0.ebuild | 116 +++++++++++++++++++++++++++++
 2 files changed, 117 insertions(+)
 create mode 100644 app-misc/fastfetch/fastfetch-2.11.0.ebuild

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 36e04934dc97..439d9d630e89 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,4 @@
 DIST fastfetch-2.10.2.tar.gz 1315785 BLAKE2B 3fbcd3023a99a2e0ddffaa576982259c3d7f0a80c8934454b1be605607871c3f19c7476e3f1d6d577012ca8dc28467ef4897a68f7332e219478af85ecea1b608 SHA512 cb74cbbba00e936f97165d93fce8f4841e73bc047ae1ac7d29343f4038dcf2f43d85ea18d26f097fde4ec09120f99167fc3f669d26c673b321cc7fbe241533d9
+DIST fastfetch-2.11.0.tar.gz 1318103 BLAKE2B 0a817e4d14b8c8e6035a20a2d08186525eb243ee8e22635684eb861f0b28137fe4027acbef03914d69abed662e1bf451fd399772a19083c44aeead0e5a01e6b1 SHA512 592957519fe6a4ac92fae1f87a0666132853cab3a1d5ff6368bd16900694835bb42949ffc510b868d505c3cff4d035d8a89e69cdbe70032085f8fe4a7cccfbc0
 DIST fastfetch-2.8.10.tar.gz 1290142 BLAKE2B 7a7ad65891850d96cc12d37b5e89359889afcdba6ccd30d834afd332ed072e00a719378ee3664a32b6e238fdca2fa1dc665768b078701b77837fefdacdce5027 SHA512 6b548c22239307f6dfcd90a4f995cbc77904adfd6f7ac809c7cd4c337a6783d768e2fd88d48e12c9b2c576893b74869d0a022f7129ccf37d853695ac3f5d488d
 DIST fastfetch-2.9.2.tar.gz 1294912 BLAKE2B 858c474d117903e990ecce4f1b9a7422da082beb79a360378ddefac1248224344a431218bb1d84b343f1ee96b044548f842ba4a04285f6e6aaaf442a92f8818b SHA512 be907b3080ff252e6c235798a6e3cb993b178a9ad02b9fd900816df560cff4f0351f212d0f00af31b671430115e5f635226bce004bb5efb7651a76f5e913a946
diff --git a/app-misc/fastfetch/fastfetch-2.11.0.ebuild b/app-misc/fastfetch/fastfetch-2.11.0.ebuild
new file mode 100644
index 000000000000..c3888b1ec46e
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.11.0.ebuild
@@ -0,0 +1,116 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.9.0
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}
-- 
cgit v1.2.3-65-gdbad