From c2a7c6225f99a625e1fdca8408875de0a40c45b2 Mon Sep 17 00:00:00 2001
From: Bernard Cafarelli <voyageur@gentoo.org>
Date: Wed, 1 Jun 2016 10:33:13 +0200
Subject: net-misc/owncloud-client: fix dolphin plugin install, bug #580752

Thank Tobias Kaminsky <tobias@kaminsky.me> for bug reports and testing
and kde team for the help

Package-Manager: portage-2.3.0_rc1
---
 .../owncloud-client-2.2.0-r1.ebuild                | 105 +++++++++++++++++++++
 1 file changed, 105 insertions(+)
 create mode 100644 net-misc/owncloud-client/owncloud-client-2.2.0-r1.ebuild

diff --git a/net-misc/owncloud-client/owncloud-client-2.2.0-r1.ebuild b/net-misc/owncloud-client/owncloud-client-2.2.0-r1.ebuild
new file mode 100644
index 000000000000..0efa6e1223e2
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.2.0-r1.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="http://owncloud.org/"
+SRC_URI="http://download.owncloud.com/desktop/stable/${P/-}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc dolphin nautilus samba +sftp test qt4 +qt5"
+
+REQUIRED_USE="^^ ( qt4 qt5 )
+	dolphin? ( qt5 )"
+
+RDEPEND=">=dev-db/sqlite-3.4:3
+	sys-fs/inotify-tools
+	virtual/libiconv
+	dolphin? (
+		>=kde-frameworks/kcoreaddons-5.16:5
+		>=kde-frameworks/kio-5.16:5 )
+	nautilus? ( dev-python/nautilus-python )
+	qt4? (
+		dev-libs/qtkeychain[qt4]
+		dev-qt/qtcore:4
+		dev-qt/qtdbus:4
+		dev-qt/qtgui:4
+		dev-qt/qtsql:4
+		dev-qt/qtwebkit:4
+		net-libs/neon[ssl]
+	)
+	qt5? (
+		dev-libs/qtkeychain[qt5]
+		dev-qt/qtconcurrent:5
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		>=dev-qt/qtnetwork-5.4:5
+		dev-qt/qtgui:5
+		dev-qt/qtquickcontrols:5
+		dev-qt/qtsql:5
+		dev-qt/qtwebkit:5[printsupport]
+	)
+	samba? ( >=net-fs/samba-3.5 )
+	sftp? ( >=net-libs/libssh-0.5 )
+	!net-misc/ocsync"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/sphinx
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( >=kde-frameworks/extra-cmake-modules-5.22.0 )
+	qt5? ( dev-qt/linguist-tools:5 )
+	test? (
+		dev-util/cmocka
+		qt4? ( dev-qt/qttest:4 )
+		qt5? ( dev-qt/qttest:5 )
+	)"
+
+S=${WORKDIR}/${P/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die "sed failed"
+
+	use nautilus || sed -i -e "s/add_subdirectory(nautilus)//" \
+		shell_integration/CMakeLists.txt || die "sed failed"
+
+	default
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DWITH_ICONV=ON
+		-DWITH_DOC=$(usex doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DBUILD_WITH_QT4=$(usex qt4)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Libsmbclient=$(usex !samba)
+		-DCMAKE_DISABLE_FIND_PACKAGE_LibSSH=$(usex !sftp)
+		-DUSE_UNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	# 1 test needs an existing ${HOME}/.config directory
+	mkdir "${T}"/.config
+	export HOME="${T}"
+	cmake-utils_src_test
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad