From c6550f2fd62ad0ef4e75b6140d7cd2c880e83ee6 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 17 Feb 2024 16:44:48 +0100
Subject: dev-qt/qtcore: drop 5.15.12-r1

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-qt/qtcore/Manifest                 |   1 -
 dev-qt/qtcore/qtcore-5.15.12-r1.ebuild | 162 ---------------------------------
 2 files changed, 163 deletions(-)
 delete mode 100644 dev-qt/qtcore/qtcore-5.15.12-r1.ebuild

diff --git a/dev-qt/qtcore/Manifest b/dev-qt/qtcore/Manifest
index a390c6270e3f..5e79c7375530 100644
--- a/dev-qt/qtcore/Manifest
+++ b/dev-qt/qtcore/Manifest
@@ -1,4 +1,3 @@
 DIST qtbase-5.15-gentoo-patchset-5.tar.xz 9116 BLAKE2B b6318fc7c3ccdbfe85d56797ffaa3b275ce3f324731caca5efb497494837ca00c020494e9f811c0d5e9a460a4d70f16291c637409e7ad72325a36bc55e113c8c SHA512 f0343bf475a86f3f73b98b166ee48b1c5c9200aac9212ad977befe05679d0c351167618b16ae958e6403f33eecdc465b26a0df5d0b83d5d57a8c85ddb8a41c9b
-DIST qtbase-5.15.12-gentoo-kde-1.tar.xz 330700 BLAKE2B d58eb3c12e4eaec9087bdf21ead08d4574fb7ce958b8453703f0b00efd27a4624329bbdf53e2c17d548e4791f7180bb3c0f68f0f3da4bc638c03622609d4df37 SHA512 f9519252a4b0451afae454155637f795688a8c9d8d40e03677430a7b887aa52d04996d93665e7068e41c8f7db428fdef933d4b8b342ea05847fffa5ddd82d1de
 DIST qtbase-5.15.12-gentoo-kde-3.tar.xz 333328 BLAKE2B f4b281098c142aeff32349a207c312de6b40057768c7732533923ddfc7db393352739a9c8b7af6a562268d2fed0397c5d5eb96a85ad376c97e7b8e51a2b962cb SHA512 6d5a826569793ae7e49f6f789d138290346be94976d3aa2c5526be9ada5dd85ffaa789422f4bedaaa6a76178e87978937be425d5f75fcce41d45726d02912c7a
 DIST qtbase-everywhere-opensource-src-5.15.12.tar.xz 50840192 BLAKE2B da758bdc13a63e8856486476733d6e9ed0bd22aa29d0d575f25a7d2ac90d0bae0d789875c747f9b16ec72941101fdf54abb64036c0fc2f0f467811bd32c7f8d9 SHA512 55ed3d73c2486a5f7cc62c0669b6344d1e4566be442bdac5849609f5ecd4fec7b74405952215e4dc018bc48a9dc2305ef50e31b61f3ace20408b5b64a2d5e888
diff --git a/dev-qt/qtcore/qtcore-5.15.12-r1.ebuild b/dev-qt/qtcore/qtcore-5.15.12-r1.ebuild
deleted file mode 100644
index 8a419f7c95fb..000000000000
--- a/dev-qt/qtcore/qtcore-5.15.12-r1.ebuild
+++ /dev/null
@@ -1,162 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-if [[ ${PV} != *9999* ]]; then
-	QT5_KDEPATCHSET_REV=1
-	KEYWORDS="amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~sparc x86"
-fi
-
-QT5_MODULE="qtbase"
-inherit linux-info flag-o-matic toolchain-funcs qt5-build
-
-DESCRIPTION="Cross-platform application development framework"
-SLOT=5/${QT5_PV}
-
-IUSE="icu old-kernel"
-
-DEPEND="
-	dev-libs/double-conversion:=
-	dev-libs/glib:2
-	dev-libs/libpcre2[pcre16,unicode]
-	sys-libs/zlib:=
-	icu? ( dev-libs/icu:= )
-	!icu? ( virtual/libiconv )
-"
-RDEPEND="${DEPEND}
-	!<dev-qt/designer-${QT5_PV}:5
-	!<dev-qt/qt3d-${QT5_PV}:5
-	!<dev-qt/qtbluetooth-${QT5_PV}:5
-	!<dev-qt/qtcharts-${QT5_PV}:5
-	!<dev-qt/qtconcurrent-${QT5_PV}:5
-	!<dev-qt/qtdatavis3d-${QT5_PV}:5
-	!<dev-qt/qtdbus-${QT5_PV}:5
-	!<dev-qt/qtdeclarative-${QT5_PV}:5
-	!<dev-qt/qtgamepad-${QT5_PV}:5
-	!<dev-qt/qtgraphicaleffects-${QT5_PV}:5
-	!<dev-qt/qtgui-${QT5_PV}:5
-	!<dev-qt/qthelp-${QT5_PV}:5
-	!<dev-qt/qtimageformats-${QT5_PV}:5
-	!<dev-qt/qtlocation-${QT5_PV}:5
-	!<dev-qt/qtmultimedia-${QT5_PV}:5
-	!<dev-qt/qtnetwork-${QT5_PV}:5
-	!<dev-qt/qtnetworkauth-${QT5_PV}:5
-	!<dev-qt/qtopengl-${QT5_PV}:5
-	!<dev-qt/qtpositioning-${QT5_PV}:5
-	!<dev-qt/qtprintsupport-${QT5_PV}:5
-	!<dev-qt/qtquickcontrols-${QT5_PV}:5
-	!<dev-qt/qtquickcontrols2-${QT5_PV}:5
-	!<dev-qt/qtquicktimeline-${QT5_PV}:5
-	!<dev-qt/qtscript-${QT5_PV}:5
-	!<dev-qt/qtscxml-${QT5_PV}:5
-	!<dev-qt/qtsensors-${QT5_PV}:5
-	!<dev-qt/qtserialbus-${QT5_PV}:5
-	!<dev-qt/qtserialport-${QT5_PV}:5
-	!<dev-qt/qtspeech-${QT5_PV}:5
-	!<dev-qt/qtsql-${QT5_PV}:5
-	!<dev-qt/qtsvg-${QT5_PV}:5
-	!<dev-qt/qttest-${QT5_PV}:5
-	!<dev-qt/qtvirtualkeyboard-${QT5_PV}:5
-	!<dev-qt/qtwayland-${QT5_PV}:5
-	!<dev-qt/qtwebchannel-${QT5_PV}:5
-	!<dev-qt/qtwebengine-${QT5_PV}:5
-	!<dev-qt/qtwebsockets-${QT5_PV}:5
-	!<dev-qt/qtwebview-${QT5_PV}:5
-	!<dev-qt/qtwidgets-${QT5_PV}:5
-	!<dev-qt/qtx11extras-${QT5_PV}:5
-	!<dev-qt/qtxml-${QT5_PV}:5
-	!<dev-qt/qtxmlpatterns-${QT5_PV}:5
-"
-
-QT5_TARGET_SUBDIRS=(
-	src/tools/bootstrap
-	src/tools/moc
-	src/tools/rcc
-	src/corelib
-	src/tools/qlalr
-	doc
-)
-
-QT5_GENTOO_PRIVATE_CONFIG=(
-	!:network
-	!:sql
-	!:testlib
-	!:xml
-)
-
-pkg_pretend() {
-	use kernel_linux || return
-	get_running_version
-	if kernel_is -lt 4 11 && ! use old-kernel; then
-		ewarn "The running kernel is older than 4.11. USE=old-kernel is needed for"
-		ewarn "dev-qt/qtcore to function on this kernel properly. Bugs #669994, #672856"
-	fi
-}
-
-src_prepare() {
-	# don't add -O3 to CXXFLAGS, bug 549140
-	sed -i -e '/CONFIG\s*+=/s/optimize_full//' src/corelib/corelib.pro || die
-
-	# fix missing qt_version_tag symbol w/ LTO, bug 674382
-	sed -i -e 's/^gcc:ltcg/gcc/' src/corelib/global/global.pri || die
-
-	# Broken with FORTIFY_SOURCE=3
-	#
-	# Our toolchain sets F_S=2 by default w/ >= -O2, so we need
-	# to unset F_S first, then explicitly set 2, to negate any default
-	# and anything set by the user if they're choosing 3 (or if they've
-	# modified GCC to set 3).
-	#
-	# Refs:
-	# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=105078
-	# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=105709
-	# https://bugreports.qt.io/browse/QTBUG-103782
-	# bug #847145
-	if tc-enables-fortify-source ; then
-		# We can't unconditionally do this b/c we fortify needs
-		# some level of optimisation.
-		filter-flags -D_FORTIFY_SOURCE=3
-		# (Qt doesn't seem to respect CPPFLAGS?)
-		append-flags -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2
-	fi
-
-	qt5-build_src_prepare
-
-	# workaround for a79a370c (...Annotate-QMutex-...patch) adding a header
-	qt5_syncqt_version
-}
-
-src_configure() {
-	local myconf=(
-		$(qt_use icu)
-		$(qt_use !icu iconv)
-	)
-	use old-kernel && myconf+=(
-		-no-feature-renameat2 # needs Linux 3.16, bug 669994
-		-no-feature-getentropy # needs Linux 3.17, bug 669994
-		-no-feature-statx # needs Linux 4.11, bug 672856
-	)
-	qt5-build_src_configure
-}
-
-src_install() {
-	qt5-build_src_install
-	qt5_symlink_binary_to_path qmake 5
-
-	local flags=(
-		DBUS FREETYPE IMAGEFORMAT_JPEG IMAGEFORMAT_PNG
-		OPENGL OPENSSL SSL WIDGETS
-	)
-
-	for flag in ${flags[@]}; do
-		cat >> "${D}"/${QT5_HEADERDIR}/QtCore/qconfig.h <<- _EOF_ || die
-
-			#if defined(QT_NO_${flag}) && defined(QT_${flag})
-			# undef QT_NO_${flag}
-			#elif !defined(QT_NO_${flag}) && !defined(QT_${flag})
-			# define QT_NO_${flag}
-			#endif
-		_EOF_
-	done
-}
-- 
cgit v1.2.3-65-gdbad