From c910c5cceeeafba155b1768ea6fb1cd94327855b Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Mon, 18 Jan 2021 13:11:10 +0100
Subject: app-doc/devmanual: New snapshot 0_pre20210118
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/765826
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 app-doc/devmanual/Manifest                       |  1 +
 app-doc/devmanual/devmanual-0_pre20210118.ebuild | 56 ++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 app-doc/devmanual/devmanual-0_pre20210118.ebuild

diff --git a/app-doc/devmanual/Manifest b/app-doc/devmanual/Manifest
index ebc70e1b5948..ac1530c9674e 100644
--- a/app-doc/devmanual/Manifest
+++ b/app-doc/devmanual/Manifest
@@ -1 +1,2 @@
 DIST devmanual-0_pre20200207.tar.xz 163940 BLAKE2B c6cf856a8f6c80b500466e27cc4106c070cff2dcf8c89d58c9ca90d03cb34a1e6a2048cb99364993f224f3497309fc24207dc44f9c14ece37c49aa602480dac0 SHA512 f6a88312e2030bf4d9fcf64bf1f38397087cb151aa41cd0c254cfc6251e4d5b291e3b361094a7c1d5fdb16e40c1702c0f0b7460ba230bfb217ad733f400c9089
+DIST devmanual-0_pre20210118.tar.xz 165436 BLAKE2B 4944a5dec564bf2165189fd026e8238132c780e4526629b8864a697600ff6ce97e8827218c4d5b121be833e8b97e1668d48d95b067e830742ea6df21894947e4 SHA512 91c7d9204998e2a09fe60ca9d195d0cd4f4b36e56e0fd9c28f98bec1b85a4e790c630a2a65688776532658c2f70ee65a74af25adacc8208414936ca3f9a80eaa
diff --git a/app-doc/devmanual/devmanual-0_pre20210118.ebuild b/app-doc/devmanual/devmanual-0_pre20210118.ebuild
new file mode 100644
index 000000000000..426aae61845f
--- /dev/null
+++ b/app-doc/devmanual/devmanual-0_pre20210118.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python3_{7,8,9})
+
+inherit python-any-r1 readme.gentoo-r1
+
+DESCRIPTION="The Gentoo Development Guide"
+HOMEPAGE="https://devmanual.gentoo.org/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/devmanual.git"
+else
+	SRC_URI="https://dev.gentoo.org/~ulm/distfiles/${P}.tar.xz"
+	S="${WORKDIR}/${PN}"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+fi
+
+LICENSE="CC-BY-SA-4.0"
+SLOT="0"
+IUSE="+offline"
+
+BDEPEND="dev-libs/libxml2
+	dev-libs/libxslt
+	gnome-base/librsvg
+	media-fonts/open-sans
+	${PYTHON_DEPS}"
+
+PATCHES=( "${FILESDIR}"/${PN}-eclasses.patch )
+
+src_compile() {
+	emake OFFLINE=$(usex offline 1 0)
+}
+
+src_install() {
+	emake OFFLINE=$(usex offline 1 0) \
+		DESTDIR="${D}" \
+		htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	local DOC_CONTENTS="In order to browse the Gentoo Development Guide in
+		offline mode, point your browser to the following url:
+		file://${EPREFIX}/usr/share/doc/${PF}/html/index.html"
+	if ! has_version app-doc/eclass-manpages; then
+		DOC_CONTENTS+="\\n\\nThe offline version of the devmanual does not
+			include the documentation for the eclasses. If you need it,
+			then emerge app-doc/eclass-manpages."
+	fi
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
-- 
cgit v1.2.3-65-gdbad