From cd14bfcaa1cde3c41ed4c926a27857a3c170d95e Mon Sep 17 00:00:00 2001
From: Martin Gysel <me@bearsh.org>
Date: Sun, 2 Apr 2023 15:37:29 +0200
Subject: dev-vcs/git-cola: add 4.2.1

Closes: https://bugs.gentoo.org/903699
Signed-off-by: Martin Gysel <me@bearsh.org>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 dev-vcs/git-cola/Manifest              |  1 +
 dev-vcs/git-cola/git-cola-4.2.1.ebuild | 76 ++++++++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)
 create mode 100644 dev-vcs/git-cola/git-cola-4.2.1.ebuild

diff --git a/dev-vcs/git-cola/Manifest b/dev-vcs/git-cola/Manifest
index 17a62a8b71c2..bf7e34b4e5fb 100644
--- a/dev-vcs/git-cola/Manifest
+++ b/dev-vcs/git-cola/Manifest
@@ -1,3 +1,4 @@
 DIST git-cola-4.0.1.tar.gz 1018819 BLAKE2B 523264bbee38526d12db5ad975d78c72ef6c0dae98566f5a8b5d51b115d222c8aa6daab838ba67fa4c697391c8f58d4b05ddb7920bf65913d217f562aabd352f SHA512 c02150997982c1f8ce65a5f021364fc4c346339f5be4104f82ba6f7688cc05bad3d764e2cf920a22c5f209dc4b857c789907ff58c0d2809bc7ca7c3481b045fd
 DIST git-cola-4.0.3.tar.gz 1131525 BLAKE2B 042ec4e0db5f9a9f947de3dcedc13c6dd2464ee29a9363f48b50622e88fbb878ed1034ff915e7a87b4a835f71dc11051e4649837e5f6de3ffe6bd84fea055d23 SHA512 06c032a9522dfefe4e95f64b00c79169da0bb68a4fc9966ac442da62cefc26a89155690b4b7bbe1fe79f8225d36e2459333bedb0cc0ef7e23521725607d9bc3b
 DIST git-cola-4.1.0.tar.gz 1140393 BLAKE2B 3236e06f86d23a7311e3cd639cbf2adcecb18810abcae938d1ff7cf25b477d814e614fffa20ce39dd9a2c6ab4f8e6b6b67f3ad3144163abe6530ac227313ca98 SHA512 4d2617947d4dbf3273f02c072de5ede10a656981f3653273780e2c1b1d3d613cd359fbb93cfb0a1d5de24b0c90818503cd9041ad3fa1a05b2ecd2db305bbe1a0
+DIST git-cola-4.2.1.tar.gz 1191680 BLAKE2B 8dd9d4b52672e32deba2f54e7f9141d3364dcbf3a823b05e766f333063a26cc49ea9e5e2f43f9492447b6b7344c930a2a1160653fb2699ff7d23cb22783f4cd1 SHA512 1a9d63c985d3566f81edd3ed3debc4d499fa5147650d479f3b1bc833d08836a17d63a8eb23c1cd5c2c31f6f7202219fb77cacb628df8f85dd3d367dcdd110891
diff --git a/dev-vcs/git-cola/git-cola-4.2.1.ebuild b/dev-vcs/git-cola/git-cola-4.2.1.ebuild
new file mode 100644
index 000000000000..3a75dac7a188
--- /dev/null
+++ b/dev-vcs/git-cola/git-cola-4.2.1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_SINGLE_IMPL=true
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 readme.gentoo-r1 virtualx xdg-utils
+
+DESCRIPTION="The highly caffeinated git GUI"
+HOMEPAGE="https://git-cola.github.io/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/PyQt5[${PYTHON_USEDEP},gui,widgets]
+		dev-python/QtPy[gui,network,${PYTHON_USEDEP}]
+		dev-python/send2trash[${PYTHON_USEDEP}]
+	')
+	dev-vcs/git
+"
+BDEPEND="sys-devel/gettext
+	$(python_gen_cond_dep "
+		test? (
+			${VIRTUALX_DEPEND}
+			dev-python/pytest[\${PYTHON_USEDEP}]
+			dev-python/PyQt5[\${PYTHON_USEDEP},gui,widgets]
+		)
+	")
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/rst-linker'
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i "s|doc/git-cola =|doc/${PF} =|" setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	cd "${T}" || die
+	GIT_CONFIG_NOSYSTEM=true LC_ALL="C.utf8" \
+	epytest "${S}"/test
+}
+
+src_compile() {
+	SETUPTOOLS_SCM_PRETEND_VERSION=${PV} distutils-r1_src_compile
+}
+
+src_install() {
+	distutils-r1_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
-- 
cgit v1.2.3-65-gdbad