From cdd4853d56b85caf76b0458f327fcb0f1bd4cfa1 Mon Sep 17 00:00:00 2001
From: Alexis Ballier <aballier@gentoo.org>
Date: Thu, 27 Oct 2022 15:00:10 +0200
Subject: media-sound/qtractor: bump to 0.9.29

Signed-off-by: Alexis Ballier <aballier@gentoo.org>
---
 media-sound/qtractor/Manifest               |   1 +
 media-sound/qtractor/qtractor-0.9.29.ebuild | 108 ++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)
 create mode 100644 media-sound/qtractor/qtractor-0.9.29.ebuild

diff --git a/media-sound/qtractor/Manifest b/media-sound/qtractor/Manifest
index 6012dbd7e25f..f4cd70c9a205 100644
--- a/media-sound/qtractor/Manifest
+++ b/media-sound/qtractor/Manifest
@@ -1 +1,2 @@
 DIST qtractor-0.9.28.tar.gz 2000685 BLAKE2B aa0d71732b9d214da22a97ca15d0c54eb61b7c35656f827bd0e39f5b55981b0c0d29645d5d3c4280ccba6aab971171615ef099f1cea1f3a8c381ac0dfffd2ca8 SHA512 db63766bcfd5a744a532d68cbe6f3153f9dd02208bca5098b27cda1cbec694b2981b3eb6a7912324c07327c000087cb5f5ba46dccc96398d051e011ce563fc67
+DIST qtractor-0.9.29.tar.gz 1988719 BLAKE2B d7f17211e885c8458c7d74d1cd0cde69d316b1765ab79bdfb3ff1abcfb35ad008f017dd12372a2fafb309a7bead0c3d31f8f1cc322da123d39760377c1883e82 SHA512 bd432e3eb2d804aacc45943c36160c938778827a1c832f30045b2456d363843ac2f77e4b2cb897b905aa026b7d9238eb2963ca1ebbd64d127d890857c5426c41
diff --git a/media-sound/qtractor/qtractor-0.9.29.ebuild b/media-sound/qtractor/qtractor-0.9.29.ebuild
new file mode 100644
index 000000000000..f3c019cec2bc
--- /dev/null
+++ b/media-sound/qtractor/qtractor-0.9.29.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
+HOMEPAGE="https://qtractor.sourceforge.io"
+SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="aubio cpu_flags_x86_sse debug dssi ladspa libsamplerate mad osc rubberband vorbis zlib"
+REQUIRED_USE="dssi? ( ladspa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/libsndfile
+	media-libs/lilv
+	media-libs/lv2
+	media-libs/suil
+	virtual/jack
+	x11-libs/libxcb:=
+	aubio? ( media-libs/aubio:= )
+	dssi? ( media-libs/dssi )
+	ladspa? ( media-libs/ladspa-sdk )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	osc? ( media-libs/liblo )
+	rubberband? ( media-libs/rubberband )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	zlib? ( sys-libs/zlib )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_DSSI=$(usex dssi 1 0)
+		-DCONFIG_GRADIENT=1
+		-DCONFIG_JACK_LATENCY=1
+		-DCONFIG_JACK_METADATA=1
+		-DCONFIG_JACK_SESSION=1
+		-DCONFIG_LADSPA=$(usex ladspa 1 0)
+		-DCONFIG_LIBAUBIO=$(usex aubio 1 0)
+		-DCONFIG_LIBLILV=1
+		-DCONFIG_LIBLO=$(usex osc 1 0)
+		-DCONFIG_LIBMAD=$(usex mad 1 0)
+		-DCONFIG_LIBRUBBERBAND=$(usex rubberband 1 0)
+		-DCONFIG_LIBSAMPLERATE=$(usex libsamplerate 1 0)
+		-DCONFIG_LIBVORBIS=$(usex vorbis 1 0)
+		-DCONFIG_LIBZ=$(usex zlib 1 0)
+		-DCONFIG_LV2=1
+		-DCONFIG_LV2_UI_GTK2=0
+		-DCONFIG_NSM=0
+		-DCONFIG_SSE=$(usex cpu_flags_x86_sse 1 0)
+		-DCONFIG_STACKTRACE=$(usex debug 1 0)
+		-DCONFIG_VESTIGE=1
+		-DCONFIG_VST=1
+		-DCONFIG_VST3=0
+		-DCONFIG_XUNIQUE=0
+	)
+	# Following options are left to the default
+	# CONFIG_LV2_ATOM
+	# CONFIG_LV2_BUF_SIZE
+	# CONFIG_LV2_CVPORT
+	# CONFIG_LV2_EVENT
+	# CONFIG_LV2_EXTERNAL_UI
+	# CONFIG_LV2_MIDNAM
+	# CONFIG_LV2_OPTIONS
+	# CONFIG_LV2_PARAMETERS
+	# CONFIG_LV2_PATCH
+	# CONFIG_LV2_PORT_EVENT
+	# CONFIG_LV2_PRESETS
+	# CONFIG_LV2_PROGRAMS
+	# CONFIG_LV2_STATE
+	# CONFIG_LV2_STATE_FILES
+	# CONFIG_LV2_STATE_MAKE_PATH
+	# CONFIG_LV2_TIME
+	# CONFIG_LV2_TIME_POSITION
+	# CONFIG_LV2_UI
+	# CONFIG_LV2_UI_IDLE
+	# CONFIG_LV2_UI_REQ_VALUE
+	# CONFIG_LV2_UI_SHOW
+	# CONFIG_LV2_UI_TOUCH
+	# CONFIG_LV2_WORKER
+	# CONFIG_LV2_UI_X11
+	cmake_src_configure
+}
-- 
cgit v1.2.3-65-gdbad