From d61dbe9fbbf29ba91958496ff6f5aa1a547d609e Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 22 Sep 2021 16:04:20 +0200
Subject: dev-qt/qtwidgets: Add IUSE=dbus to enable xdgdesktopportal build

New use flag builds Qt5 plugin for integration with flatpak and snap.

Add missing IUSE=gtk dependencies. No additional dependencies with
IUSE=dbus means the added REQUIRED_USE is cheap, and sys-apps/dbus is
already pulled in by x11-libs/gtk+3 (via dev-libs/glib) unconditionally.

Switch from ~PV to =QT5_PV* version dependencies.

Package-Manager: Portage-3.0.23, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-qt/qtwidgets/qtwidgets-5.15.2-r10.ebuild | 58 -------------------------
 dev-qt/qtwidgets/qtwidgets-5.15.2-r11.ebuild | 64 ++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+), 58 deletions(-)
 delete mode 100644 dev-qt/qtwidgets/qtwidgets-5.15.2-r10.ebuild
 create mode 100644 dev-qt/qtwidgets/qtwidgets-5.15.2-r11.ebuild

diff --git a/dev-qt/qtwidgets/qtwidgets-5.15.2-r10.ebuild b/dev-qt/qtwidgets/qtwidgets-5.15.2-r10.ebuild
deleted file mode 100644
index ebc81a5c757a..000000000000
--- a/dev-qt/qtwidgets/qtwidgets-5.15.2-r10.ebuild
+++ /dev/null
@@ -1,58 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-KDE_ORG_COMMIT=c2ea67ecefe049f6e9bb8f910d7f9c60319d8619
-QT5_MODULE="qtbase"
-inherit qt5-build
-
-DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
-
-if [[ ${QT5_BUILD_TYPE} == release ]]; then
-	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
-fi
-
-# keep IUSE defaults in sync with qtgui
-IUSE="gles2-only gtk +png +X"
-
-DEPEND="
-	~dev-qt/qtcore-${PV}:5=
-	~dev-qt/qtgui-${PV}[gles2-only=,png=,X?]
-	gtk? (
-		~dev-qt/qtgui-${PV}[dbus]
-		x11-libs/gtk+:3
-		x11-libs/libX11
-		x11-libs/pango
-	)
-"
-RDEPEND="${DEPEND}"
-
-QT5_TARGET_SUBDIRS=(
-	src/tools/uic
-	src/widgets
-	src/plugins/platformthemes
-)
-
-QT5_GENTOO_CONFIG=(
-	gtk:gtk3:
-	::widgets
-	!:no-widgets:
-)
-
-QT5_GENTOO_PRIVATE_CONFIG=(
-	:widgets
-)
-
-src_configure() {
-	local myconf=(
-		-opengl $(usex gles2-only es2 desktop)
-		$(qt_use gtk)
-		-gui
-		$(qt_use png libpng system)
-		-widgets
-		$(qt_use X xcb)
-		$(usev X '-xcb-xlib -xkbcommon')
-	)
-	qt5-build_src_configure
-}
diff --git a/dev-qt/qtwidgets/qtwidgets-5.15.2-r11.ebuild b/dev-qt/qtwidgets/qtwidgets-5.15.2-r11.ebuild
new file mode 100644
index 000000000000..4c5ad74f9d8a
--- /dev/null
+++ b/dev-qt/qtwidgets/qtwidgets-5.15.2-r11.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_COMMIT=c2ea67ecefe049f6e9bb8f910d7f9c60319d8619
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="dbus gles2-only gtk +png +X"
+
+REQUIRED_USE="gtk? ( dbus )"
+
+DEPEND="
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtgui-${QT5_PV}*:5=[gles2-only=,png=,X?]
+	dbus? ( =dev-qt/qtdbus-${QT5_PV}* )
+	gtk? (
+		dev-libs/glib:2
+		=dev-qt/qtgui-${QT5_PV}*:5=[dbus]
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/uic
+	src/widgets
+	src/plugins/platformthemes
+)
+
+QT5_GENTOO_CONFIG=(
+	dbus:xdgdesktopportal:
+	gtk:gtk3:
+	::widgets
+	!:no-widgets:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:widgets
+)
+
+src_configure() {
+	local myconf=(
+		-opengl $(usex gles2-only es2 desktop)
+		$(qt_use dbus)
+		$(qt_use gtk)
+		-gui
+		$(qt_use png libpng system)
+		-widgets
+		$(qt_use X xcb)
+		$(usev X '-xcb-xlib -xkbcommon')
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3-65-gdbad