From db61e10d2a4b10fc06967ddc272a087ede6a05db Mon Sep 17 00:00:00 2001
From: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
Date: Thu, 4 May 2023 11:32:26 +0200
Subject: media-sound/dcaenc: put dosym behind if use alsa

otherwise the configuration file does not exist so
the symlink is broken

Closes: https://bugs.gentoo.org/905694
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
---
 media-sound/dcaenc/dcaenc-3-r1.ebuild | 42 +++++++++++++++++++++++++++++++++++
 media-sound/dcaenc/dcaenc-3.ebuild    | 40 ---------------------------------
 2 files changed, 42 insertions(+), 40 deletions(-)
 create mode 100644 media-sound/dcaenc/dcaenc-3-r1.ebuild
 delete mode 100644 media-sound/dcaenc/dcaenc-3.ebuild

diff --git a/media-sound/dcaenc/dcaenc-3-r1.ebuild b/media-sound/dcaenc/dcaenc-3-r1.ebuild
new file mode 100644
index 000000000000..bcf40e35a754
--- /dev/null
+++ b/media-sound/dcaenc/dcaenc-3-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="DTS Coherent Acoustics audio encoder"
+HOMEPAGE="https://gitlab.com/patrakov/dcaenc"
+SRC_URI="https://gitlab.com/patrakov/dcaenc/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa"
+
+RDEPEND="alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-static
+		$(use_enable alsa)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${ED}" -type f -name "*.la" -delete || die
+	if use alsa; then
+		dosym ../../../usr/share/alsa/pcm/dca.conf \
+				/etc/alsa/conf.d/dca.conf
+	fi
+}
diff --git a/media-sound/dcaenc/dcaenc-3.ebuild b/media-sound/dcaenc/dcaenc-3.ebuild
deleted file mode 100644
index bc296e9146cb..000000000000
--- a/media-sound/dcaenc/dcaenc-3.ebuild
+++ /dev/null
@@ -1,40 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools multilib-minimal
-
-DESCRIPTION="DTS Coherent Acoustics audio encoder"
-HOMEPAGE="https://gitlab.com/patrakov/dcaenc"
-SRC_URI="https://gitlab.com/patrakov/dcaenc/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
-S="${WORKDIR}/${PN}-v${PV}"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="alsa"
-
-RDEPEND="alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig"
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-multilib_src_configure() {
-	local myeconfargs=(
-		--disable-static
-		$(use_enable alsa)
-	)
-	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
-}
-
-multilib_src_install_all() {
-	einstalldocs
-	find "${ED}" -type f -name "*.la" -delete || die
-	dosym ../../../usr/share/alsa/pcm/dca.conf \
-			/etc/alsa/conf.d/dca.conf
-}
-- 
cgit v1.2.3-65-gdbad