From e0d76503ba1f48d45abe952932054b3cec85b018 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Tue, 20 Feb 2024 05:19:14 +0000
Subject: net-libs/libnftnl: drop usr-ldscript

Per news item.

Signed-off-by: Sam James <sam@gentoo.org>
---
 net-libs/libnftnl/libnftnl-1.2.6-r1.ebuild | 71 ++++++++++++++++++++++++++++++
 net-libs/libnftnl/libnftnl-9999.ebuild     |  6 +--
 2 files changed, 73 insertions(+), 4 deletions(-)
 create mode 100644 net-libs/libnftnl/libnftnl-1.2.6-r1.ebuild

diff --git a/net-libs/libnftnl/libnftnl-1.2.6-r1.ebuild b/net-libs/libnftnl/libnftnl-1.2.6-r1.ebuild
new file mode 100644
index 000000000000..3559fe7f2439
--- /dev/null
+++ b/net-libs/libnftnl/libnftnl-1.2.6-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/netfilter.org.asc
+inherit linux-info verify-sig
+
+DESCRIPTION="Netlink API to the in-kernel nf_tables subsystem"
+HOMEPAGE="https://netfilter.org/projects/nftables/"
+
+if [[ ${PV} =~ ^[9]{4,}$ ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://git.netfilter.org/${PN}"
+else
+	SRC_URI="
+		https://netfilter.org/projects/${PN}/files/${P}.tar.xz
+		verify-sig? ( https://netfilter.org/projects/${PN}/files/${P}.tar.xz.sig )
+	"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+	BDEPEND+="verify-sig? ( sec-keys/openpgp-keys-netfilter )"
+fi
+
+LICENSE="GPL-2"
+SLOT="0/11" # libnftnl.so version
+IUSE="examples static-libs test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=net-libs/libmnl-1.0.4:=
+"
+BDEPEND+="
+	virtual/pkgconfig
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	if kernel_is ge 3 13; then
+		CONFIG_CHECK="~NF_TABLES"
+		linux-info_pkg_setup
+	else
+		eerror "This package requires kernel version 3.13 or newer to work properly."
+	fi
+}
+
+src_prepare() {
+	default
+
+	[[ ${PV} =~ ^[9]{4,}$ ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+
+	if use examples; then
+		find examples/ -name 'Makefile*' -delete || die "Could not rm examples"
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
diff --git a/net-libs/libnftnl/libnftnl-9999.ebuild b/net-libs/libnftnl/libnftnl-9999.ebuild
index d6549d72523b..3559fe7f2439 100644
--- a/net-libs/libnftnl/libnftnl-9999.ebuild
+++ b/net-libs/libnftnl/libnftnl-9999.ebuild
@@ -1,10 +1,10 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/netfilter.org.asc
-inherit linux-info usr-ldscript verify-sig
+inherit linux-info verify-sig
 
 DESCRIPTION="Netlink API to the in-kernel nf_tables subsystem"
 HOMEPAGE="https://netfilter.org/projects/nftables/"
@@ -61,8 +61,6 @@ src_configure() {
 src_install() {
 	default
 
-	gen_usr_ldscript -a nftnl
-
 	find "${ED}" -type f -name '*.la' -delete || die
 
 	if use examples; then
-- 
cgit v1.2.3-65-gdbad