From ed5b368d39ed8cdb5e32e15d4068bdffc610cb9f Mon Sep 17 00:00:00 2001
From: Maciej Barć <xgqt@gentoo.org>
Date: Mon, 3 Jul 2023 09:57:05 +0200
Subject: sys-apps/system-monitoring-center: add live
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 .../system-monitoring-center-9999.ebuild           | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 sys-apps/system-monitoring-center/system-monitoring-center-9999.ebuild

diff --git a/sys-apps/system-monitoring-center/system-monitoring-center-9999.ebuild b/sys-apps/system-monitoring-center/system-monitoring-center-9999.ebuild
new file mode 100644
index 000000000000..76cc6a9cbef0
--- /dev/null
+++ b/sys-apps/system-monitoring-center/system-monitoring-center-9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit meson python-single-r1 xdg
+
+DESCRIPTION="Multi-featured system monitor GUI written in Python"
+HOMEPAGE="https://github.com/hakandundar34coding/system-monitoring-center/"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/hakandundar34coding/${PN}.git"
+else
+	SRC_URI="https://github.com/hakandundar34coding/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	gui-libs/gtk:4[introspection]
+	sys-apps/dmidecode
+	sys-apps/hwdata
+	$(python_gen_cond_dep '
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+"
+
+src_install() {
+	meson_src_install
+	python_optimize "${ED}"/usr/share/${PN}
+
+	mv "${ED}"/usr/share/appdata "${ED}"/usr/share/metainfo || die
+}
-- 
cgit v1.2.3-65-gdbad