From ef03593d1c5d3bddefee7a90d9417556234dd90c Mon Sep 17 00:00:00 2001
From: Michael Weber <xmw@gentoo.org>
Date: Fri, 29 Sep 2017 07:33:42 +0200
Subject: app-misc/qlcplus: inherit xdg for xdg_desktop_database_update, fix
 sandbox violation https://bugs.gentoo.org/621500#c2.

Package-Manager: Portage-2.3.10, Repoman-2.3.3
---
 app-misc/qlcplus/qlcplus-4.10.5b-r2.ebuild | 59 ++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 app-misc/qlcplus/qlcplus-4.10.5b-r2.ebuild

diff --git a/app-misc/qlcplus/qlcplus-4.10.5b-r2.ebuild b/app-misc/qlcplus/qlcplus-4.10.5b-r2.ebuild
new file mode 100644
index 000000000000..9d50c6300aa1
--- /dev/null
+++ b/app-misc/qlcplus/qlcplus-4.10.5b-r2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit qmake-utils udev vcs-snapshot virtualx xdg
+
+DESCRIPTION="QLC+ - Q Light Controller Plus to control DMX interfaces"
+HOMEPAGE="http://www.qlcplus.org/"
+SRC_URI="https://github.com/mcallegari/${PN}/archive/QLC+_${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+	|| ( dev-embedded/libftdi:1 dev-embedded/libftdi:0 )
+	dev-libs/glib:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5[widgets]
+	dev-qt/qtnetwork:5
+	dev-qt/qtscript:5
+	dev-qt/qttest:5
+	dev-qt/qtwidgets:5
+	media-libs/alsa-lib
+	media-libs/libmad
+	media-libs/libsndfile
+	sci-libs/fftw:3.0
+	virtual/libusb:0
+	virtual/libusb:1
+	virtual/udev
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	sed -e "s:/etc/udev/rules.d:${EROOT}lib/udev/rules.d:" -i \
+		plugins/hid/hid.pro \
+		plugins/udmx/src/src.pro \
+		plugins/dmxusb/src/src.pro \
+		plugins/spi/spi.pro \
+		plugins/peperoni/unix/unix.pro || die
+	sed -e "/UDEVRULESDIR/s:/etc/udev/rules.d:$(get_udevdir)/rules.d:" \
+		-i variables.pri || die
+}
+
+src_configure() {
+	eqmake5
+
+	# sandbox error "mkdir /usr/share/qlcplus" 
+	# see https://bugs.gentoo.org/621500#c2
+	export INSTALL_ROOT="${D}"
+}
+
+src_test() {
+	virtx emake check
+}
-- 
cgit v1.2.3-65-gdbad