From ef5003ccecfcfb64bdcceb46100cd8805f26be34 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sat, 25 Feb 2023 10:56:27 +0100
Subject: dev-libs/libixion: python3_11

Tests pass.

Closes: https://bugs.gentoo.org/896714
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-libs/libixion/libixion-0.17.0-r1.ebuild | 57 +++++++++++++++++++++++++++++
 dev-libs/libixion/libixion-9999.ebuild      |  7 ++--
 2 files changed, 60 insertions(+), 4 deletions(-)
 create mode 100644 dev-libs/libixion/libixion-0.17.0-r1.ebuild

diff --git a/dev-libs/libixion/libixion-0.17.0-r1.ebuild b/dev-libs/libixion/libixion-0.17.0-r1.ebuild
new file mode 100644
index 000000000000..fa8b08196511
--- /dev/null
+++ b/dev-libs/libixion/libixion-0.17.0-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit python-single-r1
+
+DESCRIPTION="General purpose formula parser & interpreter"
+HOMEPAGE="https://gitlab.com/ixion/ixion"
+
+if [[ ${PV} == *9999* ]]; then
+	MDDS_SLOT="1/9999"
+	EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
+	inherit git-r3 autotools
+else
+	MDDS_SLOT="1/2.0"
+	SRC_URI="https://kohei.us/files/ixion/src/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0/0.17" # based on SONAME of libixion.so
+IUSE="debug python"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	dev-libs/boost:=
+	dev-util/mdds:${MDDS_SLOT}
+	python? ( ${PYTHON_DEPS} )
+"
+DEPEND="${RDEPEND}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable debug debug-utils)
+		$(use_enable debug log-debug)
+		$(use_enable python)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -type f -delete || die
+}
diff --git a/dev-libs/libixion/libixion-9999.ebuild b/dev-libs/libixion/libixion-9999.ebuild
index bdf365c4dc51..c20b5d4c5596 100644
--- a/dev-libs/libixion/libixion-9999.ebuild
+++ b/dev-libs/libixion/libixion-9999.ebuild
@@ -3,14 +3,13 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9..10} )
-
+PYTHON_COMPAT=( python3_{9..11} )
 inherit python-single-r1
 
 DESCRIPTION="General purpose formula parser & interpreter"
 HOMEPAGE="https://gitlab.com/ixion/ixion"
 
-if [[ ${PV} == *9999 ]]; then
+if [[ ${PV} == *9999* ]]; then
 	MDDS_SLOT="1/9999"
 	EGIT_REPO_URI="https://gitlab.com/ixion/ixion.git"
 	inherit git-r3 autotools
@@ -39,7 +38,7 @@ pkg_setup() {
 
 src_prepare() {
 	default
-	[[ ${PV} == *9999 ]] && eautoreconf
+	[[ ${PV} == *9999* ]] && eautoreconf
 }
 
 src_configure() {
-- 
cgit v1.2.3-65-gdbad