From f1f53e3c17d4df91b075d92cdf061437040df9b8 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Sun, 7 Jun 2020 23:23:06 +0300
Subject: net-vpn/networkmanager-openvpn: bump to 1.8.12

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 net-vpn/networkmanager-openvpn/Manifest            |  1 +
 .../networkmanager-openvpn-1.8.12.ebuild           | 58 ++++++++++++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 net-vpn/networkmanager-openvpn/networkmanager-openvpn-1.8.12.ebuild

diff --git a/net-vpn/networkmanager-openvpn/Manifest b/net-vpn/networkmanager-openvpn/Manifest
index 8e0a525ad42e..7aa969f5114d 100644
--- a/net-vpn/networkmanager-openvpn/Manifest
+++ b/net-vpn/networkmanager-openvpn/Manifest
@@ -1 +1,2 @@
 DIST NetworkManager-openvpn-1.8.10.tar.xz 564540 BLAKE2B e117395b91efbd0ee10bdefe0aaff8a39fdd1fe232dc1543224be7dfd9bb18729ad873091301e6348f8955f28579e106f5565c7138309571e06598aa35dc5bba SHA512 f710848fccf21ac4554a2b46e80cf890c011edc6d64d9a49d6d8669f3ff71f7990e11e6f4681bb85d30238ec05f2fc79c4619983f6860c6ab0d714f941a3dfcc
+DIST NetworkManager-openvpn-1.8.12.tar.xz 597216 BLAKE2B 55ccb3139b1be9d1894d3651d60ce0f2167a24efbb24a9870eb4bb683a91603ae5f5149ed9aca8307cf608140c075a7b19bdfef68b1dbfe0729c117f084bb904 SHA512 1b8adf926426f866f7509a07c24203d6b584627aba4f8e2b1b00fa897bf0d7155009d566c3440565d1ee0e938694dd8d6746f37f62d493864d16eae007590b22
diff --git a/net-vpn/networkmanager-openvpn/networkmanager-openvpn-1.8.12.ebuild b/net-vpn/networkmanager-openvpn/networkmanager-openvpn-1.8.12.ebuild
new file mode 100644
index 000000000000..513bba285b9a
--- /dev/null
+++ b/net-vpn/networkmanager-openvpn/networkmanager-openvpn-1.8.12.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME_ORG_MODULE="NetworkManager-${PN##*-}"
+
+inherit gnome2 user
+
+DESCRIPTION="NetworkManager OpenVPN plugin"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gtk test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	>=net-misc/networkmanager-1.7.0:=
+	>=net-vpn/openvpn-2.1
+	gtk? (
+		>=app-crypt/libsecret-0.18
+		>=net-libs/libnma-1.7.0
+		>=x11-libs/gtk+-3.4:3
+	)
+"
+DEPEND="${RDEPEND}
+	dev-libs/libxml2:2
+	sys-devel/gettext
+	>=dev-util/intltool-0.35
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	enewgroup nm-openvpn
+	enewuser nm-openvpn -1 -1 -1 nm-openvpn
+}
+
+src_prepare() {
+	# Test will fail if the machine doesn't have a particular locale installed
+	# FAIL: (tls-import-data) unexpected 'ca' secret value, upstream bug #742708
+	sed '/test_non_utf8_import (plugin, test_dir)/ d' \
+		-i properties/tests/test-import-export.c || die "sed failed"
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# --localstatedir=/var needed per bug #536248
+	gnome2_src_configure \
+		--localstatedir=/var \
+		--disable-more-warnings \
+		--disable-static \
+		--with-dist-version=Gentoo \
+		$(use_with gtk gnome) \
+		--without-libnm-glib
+}
-- 
cgit v1.2.3-65-gdbad