From f2a331b3a89d33f6f56c520b98ad10d2201c5936 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Mon, 30 Oct 2023 18:51:59 +0100
Subject: dev-python/pypdf: Bump to 3.17.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pypdf/Manifest            |  1 +
 dev-python/pypdf/pypdf-3.17.0.ebuild | 59 ++++++++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 dev-python/pypdf/pypdf-3.17.0.ebuild

diff --git a/dev-python/pypdf/Manifest b/dev-python/pypdf/Manifest
index d39dff6e24b4..b472b6e1f8fa 100644
--- a/dev-python/pypdf/Manifest
+++ b/dev-python/pypdf/Manifest
@@ -1,2 +1,3 @@
 DIST pypdf-3.16.4.gh.tar.gz 7970008 BLAKE2B 86f622cf1ff6632a4645d564336fd8948970579f6bae241437701f333c2f336feab55f7e32a35b4f480577fe609958f492e73c1c9c5f1471af08e34c157f06b0 SHA512 7e7eb9759dfb3984b384a721e7d90ab5c666630bd3c56d936260e5ad93cfdc9a2d6fff8a7354764125923ab8f029ac5366a2750cc1151676fb40be1eba1bb2a4
+DIST pypdf-3.17.0.gh.tar.gz 7974585 BLAKE2B e09840119845cf6b14887081f367b2a7ff9a88e4713cd1a940276ca0f83b6497ee07336ff02e7c43571cb39782e72f4f0b206fb3f692476e98d5c291b0193a25 SHA512 31b0298c26c117764494906ef940cb8f111d5b57b91849fbffb6a63682089e5bc0c59a4c068c90810f5d21ce67c8d71fb0c42d996f441bc287ad73e0c4710d97
 DIST pypdf-sample-files-d87c33efc0f98225132dfe9c47980208b8130aa4.gh.tar.gz 11645535 BLAKE2B 3f96adaf4abc50a4390d9432878571a0ef9dd43dd34f307bb4bb6fd110d5ecdde988578860f110a6c8578cef96eac5410ded3204989fd20e6a6f1a84fac2fe83 SHA512 cb68a2eb06ef6738bef979f3b20c66fb925fbcb029cb22dfa5ea9b23b71ba07cb8e364e14eca34ebeb3b11e367c94738e32c9067b56b4da505bf77ab402abd06
diff --git a/dev-python/pypdf/pypdf-3.17.0.ebuild b/dev-python/pypdf/pypdf-3.17.0.ebuild
new file mode 100644
index 000000000000..aea5f7f1d1bd
--- /dev/null
+++ b/dev-python/pypdf/pypdf-3.17.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+SAMPLE_COMMIT=d87c33efc0f98225132dfe9c47980208b8130aa4
+DESCRIPTION="Python library to work with PDF files"
+HOMEPAGE="
+	https://pypi.org/project/pypdf/
+	https://github.com/py-pdf/pypdf/
+"
+SRC_URI="
+	https://github.com/py-pdf/pypdf/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/py-pdf/sample-files/archive/${SAMPLE_COMMIT}.tar.gz
+			-> ${PN}-sample-files-${SAMPLE_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		>=dev-python/pillow-8.0.0[jpeg,jpeg2k,tiff,${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# rely on -Werror
+	tests/test_utils.py::test_deprecate_no_replacement
+	tests/test_workflows.py::test_orientations
+	tests/test_writer.py::test_remove_image_per_type
+	# TODO: requires fpdf
+	tests/test_page.py::test_compression
+	tests/test_writer.py::test_merging_many_temporary_files
+)
+
+src_unpack() {
+	default
+	if use test; then
+		mv "sample-files-${SAMPLE_COMMIT}"/* "${S}"/sample-files/ || die
+	fi
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts= -m "not enable_socket"
+}
-- 
cgit v1.2.3-65-gdbad