From f2e52c0d1fabc9b06e1da62f378f277701407b98 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sat, 7 Jan 2023 07:16:23 +0000
Subject: media-libs/avidemux-plugins: add 2.8.1

Bug: https://bugs.gentoo.org/830464
Signed-off-by: Sam James <sam@gentoo.org>
---
 media-libs/avidemux-plugins/Manifest               |   1 +
 .../avidemux-plugins/avidemux-plugins-2.8.1.ebuild | 166 +++++++++++++++++++++
 .../avidemux-plugins-2.8.1-optional-pulse.patch    |  20 +++
 3 files changed, 187 insertions(+)
 create mode 100644 media-libs/avidemux-plugins/avidemux-plugins-2.8.1.ebuild
 create mode 100644 media-libs/avidemux-plugins/files/avidemux-plugins-2.8.1-optional-pulse.patch

diff --git a/media-libs/avidemux-plugins/Manifest b/media-libs/avidemux-plugins/Manifest
index f4c59a24eb9f..5e1a60fccafb 100644
--- a/media-libs/avidemux-plugins/Manifest
+++ b/media-libs/avidemux-plugins/Manifest
@@ -1 +1,2 @@
 DIST avidemux-2.7.8.tar.gz 22080267 BLAKE2B a1e56856f44d56afac6ea4015f206a3f9301c025b3c8da1528165bd4c139ccc971074ac21aa05b9b3dfd6d514eabcbb375e671c8df9c9e5cae74a0a6597577c4 SHA512 6cd5527ab34517a07bf73e46d01f15b7ff023ff34ed70ee54f1d7dbfb6cf57364a323b4ecb89bb9aadeb9bc05473aacb40d8c4eecc522840a3c1c4b3a8756d82
+DIST avidemux-2.8.1.tar.gz 23207741 BLAKE2B 766ae9b159d2e48a3d14bdfccf9c665b95ed056831b515d53837bf2bae20baf9b01d15d551b62fb96f3c0cf50b0138448a133bc62e6202af744de558e0fbfe4f SHA512 e7105e555e04dd6768336bdb246037e91045de2e1f572ae362d985424def65499c7f25d92d376ea98af09b436d89e9eb4a5424e93b11df14f2d67ac35661a8a3
diff --git a/media-libs/avidemux-plugins/avidemux-plugins-2.8.1.ebuild b/media-libs/avidemux-plugins/avidemux-plugins-2.8.1.ebuild
new file mode 100644
index 000000000000..3c95dfdc5b08
--- /dev/null
+++ b/media-libs/avidemux-plugins/avidemux-plugins-2.8.1.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit cmake flag-o-matic python-single-r1
+
+DESCRIPTION="Plugins for the video editor media-video/avidemux"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> avidemux-${PV}.tar.gz"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 LGPL-2.1 MIT OFL-1.1 PSF-2 public-domain"
+SLOT="2.7"
+IUSE="a52 aac aften alsa amr dcaenc debug dts fdk fontconfig fribidi jack lame libsamplerate cpu_flags_x86_mmx nvenc opengl opus oss pulseaudio gui truetype twolame vdpau vorbis vpx x264 x265 xv xvid"
+KEYWORDS="~amd64 ~x86"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# dev-lang/spidermonkey is not required anymore
+# see https://github.com/mean00/avidemux2/blob/master/avidemux_plugins/ADM_scriptEngines/CMakeLists.txt
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	~media-libs/avidemux-core-${PV}:${SLOT}[vdpau?]
+	~media-video/avidemux-${PV}:${SLOT}[opengl?,gui?]
+	dev-libs/libxml2:2
+	media-libs/a52dec
+	media-libs/libass:0=
+	media-libs/libmad
+	media-libs/libmp4v2
+	media-libs/libpng:0=
+	virtual/libiconv
+	aac? (
+		media-libs/faac
+		media-libs/faad2
+	)
+	aften? ( media-libs/aften )
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	dcaenc? ( media-sound/dcaenc )
+	dts? ( media-libs/libdca )
+	fdk? ( media-libs/fdk-aac:0= )
+	fontconfig? ( media-libs/fontconfig:1.0 )
+	fribidi? ( dev-libs/fribidi )
+	jack? (
+		virtual/jack
+		libsamplerate? ( media-libs/libsamplerate )
+	)
+	lame? ( media-sound/lame )
+	nvenc? ( amd64? ( media-libs/nv-codec-headers ) )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	gui? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	truetype? ( media-libs/freetype:2 )
+	twolame? ( media-sound/twolame )
+	vorbis? ( media-libs/libvorbis )
+	vpx? ( media-libs/libvpx:0= )
+	x264? ( media-libs/x264:0= )
+	x265? ( media-libs/x265:0= )
+	xv? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXv
+	)
+	xvid? ( media-libs/xvid )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	oss? ( virtual/os-headers )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	!<media-libs/avidemux-plugins-${PV}
+"
+
+S="${WORKDIR}/avidemux2-${PV}"
+
+PATCHES=( "${FILESDIR}/${PN}-2.8.1-optional-pulse.patch" )
+
+src_prepare() {
+	default
+
+	# Don't reapply PATCHES during cmake_src_prepare
+	unset PATCHES
+
+	processes="buildPluginsCommon:avidemux_plugins
+		buildPluginsCLI:avidemux_plugins"
+	use gui && processes+=" buildPluginsQt4:avidemux_plugins"
+
+	for process in ${processes} ; do
+		CMAKE_USE_DIR="${S}"/${process#*:} cmake_src_prepare
+	done
+}
+
+src_configure() {
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+
+		local mycmakeargs=(
+			-DAVIDEMUX_SOURCE_DIR='${S}'
+			-DPLUGIN_UI=$(echo ${build/buildPlugins/} | tr '[:lower:]' '[:upper:]')
+			-DFAAC="$(usex aac)"
+			-DFAAD="$(usex aac)"
+			-DALSA="$(usex alsa)"
+			-DAFTEN="$(usex aften)"
+			-DDCAENC="$(usex dcaenc)"
+			-DFDK_AAC="$(usex fdk)"
+			-DOPENCORE_AMRWB="$(usex amr)"
+			-DOPENCORE_AMRNB="$(usex amr)"
+			-DLIBDCA="$(usex dts)"
+			-DFONTCONFIG="$(usex fontconfig)"
+			-DJACK="$(usex jack)"
+			-DLAME="$(usex lame)"
+			-DNVENC="$(usex nvenc)"
+			-DOPENGL="$(usex opengl)"
+			-DOPUS="$(usex opus)"
+			-DOSS="$(usex oss)"
+			-DPULSEAUDIO="$(usex pulseaudio)"
+			-DENABLE_QT4=OFF
+			-DENABLE_QT6=OFF
+			-DFREETYPE2="$(usex truetype)"
+			-DTWOLAME="$(usex twolame)"
+			-DX264="$(usex x264)"
+			-DX265="$(usex x265)"
+			-DXVIDEO="$(usex xv)"
+			-DXVID="$(usex xvid)"
+			-DVDPAU="$(usex vdpau)"
+			-DVORBIS="$(usex vorbis)"
+			-DLIBVORBIS="$(usex vorbis)"
+			-DVPXDEC="$(usex vpx)"
+			-DUSE_EXTERNAL_LIBA52=yes
+			-DUSE_EXTERNAL_LIBASS=yes
+			-DUSE_EXTERNAL_LIBMAD=yes
+			-DUSE_EXTERNAL_LIBMP4V2=yes
+		)
+
+		use gui && mycmakeargs+=( -DENABLE_QT5=True )
+		use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+
+		CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake_src_configure
+	done
+}
+
+src_compile() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_compile
+	done
+}
+
+src_install() {
+	for process in ${processes} ; do
+		local build="${WORKDIR}/${P}_build/${process%%:*}"
+		BUILD_DIR="${build}" cmake_src_install
+	done
+}
diff --git a/media-libs/avidemux-plugins/files/avidemux-plugins-2.8.1-optional-pulse.patch b/media-libs/avidemux-plugins/files/avidemux-plugins-2.8.1-optional-pulse.patch
new file mode 100644
index 000000000000..29926c59efde
--- /dev/null
+++ b/media-libs/avidemux-plugins/files/avidemux-plugins-2.8.1-optional-pulse.patch
@@ -0,0 +1,20 @@
+--- a/cmake/admCheckAudioDeviceLibs.cmake
++++ b/cmake/admCheckAudioDeviceLibs.cmake
+@@ -194,6 +194,7 @@
+ 		APPEND_SUMMARY_LIST("Audio Device" "PulseAudioS" "${USE_PULSE_SIMPLE}")
+ ]]
+     OPTION(PULSEAUDIO "" ON)
++    IF (PULSEAUDIO)
+     MESSAGE(STATUS "Checking for PulseAudio")
+     include(FindPkgConfig)
+     pkg_check_modules(PULSEAUDIO libpulse)
+@@ -203,6 +204,9 @@
+     ELSE (PULSEAUDIO_FOUND)
+         MESSAGE(STATUS "Could not find PulseAudio")
+     ENDIF (PULSEAUDIO_FOUND)
++    ELSE (PULSEAUDIO)
++	MESSAGE("${MSG_DISABLE_OPTION}")
++    ENDIF (PULSEAUDIO)
+     APPEND_SUMMARY_LIST("Audio Device" "PulseAudio" "${USE_PULSE}")
+ ELSE (UNIX AND NOT APPLE)
+ 	SET(PULSEAUDIOSIMPLE_CAPABLE FALSE)
-- 
cgit v1.2.3-65-gdbad