From f8061de6bfae567d3e7c8dbf72bd3080b52f24c9 Mon Sep 17 00:00:00 2001
From: Michael Vetter <jubalh@iodoru.org>
Date: Sun, 27 Aug 2023 09:21:29 +0000
Subject: net-im/profanity: add use flag to add support of python plugins

Signed-off-by: Michael Vetter <jubalh@iodoru.org>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 net-im/profanity/metadata.xml               |  1 +
 net-im/profanity/profanity-0.14.0-r1.ebuild | 85 +++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)
 create mode 100644 net-im/profanity/profanity-0.14.0-r1.ebuild

diff --git a/net-im/profanity/metadata.xml b/net-im/profanity/metadata.xml
index 615f8cd4c2ef..7b75b4cdd81c 100644
--- a/net-im/profanity/metadata.xml
+++ b/net-im/profanity/metadata.xml
@@ -18,6 +18,7 @@
 		<flag name="omemo">Enable OMEMO encryption</flag>
 		<flag name="omemo-qrcode">Enable exchanging OMEMO information via QR code</flag>
 		<flag name="otr">Enable encrypted conversations using Off-The-Records messaging</flag>
+		<flag name="python">Enable Python plugins support</flag>
 	</use>
 	<upstream>
 		<remote-id type="github">profanity-im/profanity</remote-id>
diff --git a/net-im/profanity/profanity-0.14.0-r1.ebuild b/net-im/profanity/profanity-0.14.0-r1.ebuild
new file mode 100644
index 000000000000..537409d27d05
--- /dev/null
+++ b/net-im/profanity/profanity-0.14.0-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit python-single-r1
+
+DESCRIPTION="A console based XMPP client inspired by Irssi"
+HOMEPAGE="https://profanity-im.github.io"
+SRC_URI="https://github.com/profanity-im/profanity/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="libnotify omemo omemo-qrcode otr gpg test xscreensaver python"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="omemo-qrcode? ( omemo ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	>=dev-libs/libstrophe-0.12.3:=
+	media-libs/harfbuzz:=
+	net-misc/curl
+	sys-libs/ncurses:=[unicode(+)]
+	sys-libs/readline:=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango
+	x11-misc/shared-mime-info
+	gpg? ( app-crypt/gpgme:= )
+	libnotify? ( x11-libs/libnotify )
+	omemo? (
+		dev-libs/libgcrypt:=
+		net-libs/libsignal-protocol-c
+	)
+	omemo-qrcode? ( media-gfx/qrencode:= )
+	otr? ( net-libs/libotr )
+	python? ( ${PYTHON_DEPS} )
+	xscreensaver? (
+		x11-libs/libXScrnSaver
+		x11-libs/libX11
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-util/cmocka )
+    python? (
+	  $(python_gen_cond_dep '
+        dev-python/cython[${PYTHON_USEDEP}]
+      ')
+   )
+"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-gdk-pixbuf
+		$(use_enable libnotify notifications)
+		$(use_enable omemo)
+		$(use_enable omemo-qrcode)
+		$(use_enable otr)
+		$(use_enable python python-plugins)
+		$(use_enable gpg pgp)
+		$(use_with xscreensaver)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake CFLAGS="${CFLAGS}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -type f -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad