From fc7e885bf5412e5fd096290b92dd7006a4b36521 Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Tue, 21 Jan 2020 22:50:50 +0100
Subject: app-text/expander: Port to EAPI 7

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: David Seifert <soap@gentoo.org>
---
 app-text/expander/expander-2.0.5-r2.ebuild | 32 ++++++++++--------------------
 1 file changed, 11 insertions(+), 21 deletions(-)

diff --git a/app-text/expander/expander-2.0.5-r2.ebuild b/app-text/expander/expander-2.0.5-r2.ebuild
index 1c4a5c12ffbd..c1ddd2ee423e 100644
--- a/app-text/expander/expander-2.0.5-r2.ebuild
+++ b/app-text/expander/expander-2.0.5-r2.ebuild
@@ -1,9 +1,9 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=4
+EAPI=7
 
-inherit eutils toolchain-funcs
+inherit toolchain-funcs
 
 DESCRIPTION="Expander is a utility that acts as a filter for text editors"
 HOMEPAGE="http://www.nedit.org"
@@ -12,35 +12,25 @@ SRC_URI="ftp://ftp.nedit.org/pub/contrib/misc/nedit_expander_kit_2.05.tar.gz"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86 ~x86-linux ~ppc-macos"
-IUSE=""
 
-S=${WORKDIR}/${PN}
+S="${WORKDIR}/${PN}"
 
-src_prepare() {
-	epatch "${FILESDIR}"/${P}-gentoo.patch
-}
+PATCHES=( "${FILESDIR}"/${P}-gentoo.patch )
 
 src_compile() {
 	emake -C src CC=$(tc-getCC)
 }
 
 src_install() {
-	cd src
-	dobin expander boxcomment align_columns align_comments where_is
+	dobin src/{expander,boxcomment,align_columns,align_comments,where_is}
 	dosym boxcomment /usr/bin/unboxcomment
 
-	insinto /usr/share/${P}
-	doins "${S}"/service
-	for x in defs macros misc templates ; do
-		insinto /usr/share/${P}/${x}
-		doins "${S}"/${x}/*
-	done
-
-	cd "${S}"/docs
-	doman *.1
+	einstalldocs
+	dodoc USAGE
+	doman docs/*.1
 
-	cd "${S}"
-	dodoc ChangeLog INSTALL README USAGE
+	insinto /usr/share/${P}
+	doins -r service defs macros misc templates
 }
 
 pkg_postinst() {
-- 
cgit v1.2.3-65-gdbad