From 629c12eac77f710cf35f1a7572bcfaa79d4c7053 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Fri, 28 Jan 2022 07:12:56 +0000
Subject: app-accessibility/espeak-ng: allow using  app-text/ronn-ng for
 USE=man

app-text/ronn will be last-rited soon.

Bug: https://bugs.gentoo.org/770907
Signed-off-by: Sam James <sam@gentoo.org>
---
 .../espeak-ng/espeak-ng-1.50-r1.ebuild             | 80 ++++++++++++++++++++++
 app-accessibility/espeak-ng/espeak-ng-9999.ebuild  |  4 +-
 2 files changed, 82 insertions(+), 2 deletions(-)
 create mode 100644 app-accessibility/espeak-ng/espeak-ng-1.50-r1.ebuild

(limited to 'app-accessibility/espeak-ng')

diff --git a/app-accessibility/espeak-ng/espeak-ng-1.50-r1.ebuild b/app-accessibility/espeak-ng/espeak-ng-1.50-r1.ebuild
new file mode 100644
index 000000000000..95392dcb4fcb
--- /dev/null
+++ b/app-accessibility/espeak-ng/espeak-ng-1.50-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Software speech synthesizer for English, and some other languages"
+HOMEPAGE="https://github.com/espeak-ng/espeak-ng"
+SRC_URI="https://github.com/espeak-ng/espeak-ng/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+ Turkowski unicode"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="+async +klatt l10n_ru l10n_zh man mbrola +sound"
+
+COMMON_DEPEND="
+	!app-accessibility/espeak
+	mbrola? ( app-accessibility/mbrola )
+	sound? ( media-libs/pcaudiolib )
+"
+DEPEND="${COMMON_DEPEND}"
+RDEPEND="${COMMON_DEPEND}
+	sound? ( media-sound/sox )
+"
+BDEPEND="
+	virtual/pkgconfig
+	man? ( || ( app-text/ronn-ng app-text/ronn ) )
+"
+
+DOCS=( CHANGELOG.md README.md docs )
+
+src_prepare() {
+	default
+
+	# disable failing tests
+	rm tests/{language-pronunciation,translate}.test || die
+	sed -i \
+		-e "/language-pronunciation.check/d" \
+		-e "/translate.check/d" \
+		Makefile.am || die
+
+	# https://github.com/espeak-ng/espeak-ng/issues/699
+	# fixed in master
+	sed -i -e "s/int samplerate;/static int samplerate;/" src/espeak-ng.c || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local econf_args
+	econf_args=(
+		$(use_with async)
+		$(use_with klatt)
+		$(use_with l10n_ru extdict-ru)
+		$(use_with l10n_zh extdict-zh)
+		$(use_with l10n_zh extdict-zhy)
+		$(use_with mbrola)
+		$(use_with sound pcaudiolib)
+		--without-libfuzzer
+		--without-sonic
+		--disable-rpath
+		--disable-static
+	)
+	econf "${econf_args[@]}"
+}
+
+src_compile() {
+	# see docs/building.md
+	emake -j1
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	emake DESTDIR="${D}" VIMDIR=/usr/share/vimfiles install
+	rm "${ED}"/usr/lib*/*.la || die
+}
diff --git a/app-accessibility/espeak-ng/espeak-ng-9999.ebuild b/app-accessibility/espeak-ng/espeak-ng-9999.ebuild
index 941edd1d327b..dfba4f0058bf 100644
--- a/app-accessibility/espeak-ng/espeak-ng-9999.ebuild
+++ b/app-accessibility/espeak-ng/espeak-ng-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -31,7 +31,7 @@ RDEPEND="${COMMON_DEPEND}
 "
 BDEPEND="
 	virtual/pkgconfig
-	man? ( app-text/ronn )
+	man? ( || ( app-text/ronn-ng app-text/ronn ) )
 "
 
 DOCS=( CHANGELOG.md README.md docs )
-- 
cgit v1.2.3-65-gdbad