From 20d02b9496e7ac8a17bd533740c09b579c6a9405 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Thu, 3 Jan 2019 05:48:30 +0100
Subject: app-arch/xarchiver: Bump to 0.5.4.14
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 app-arch/xarchiver/xarchiver-0.5.4.14.ebuild | 62 ++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 app-arch/xarchiver/xarchiver-0.5.4.14.ebuild

(limited to 'app-arch/xarchiver/xarchiver-0.5.4.14.ebuild')

diff --git a/app-arch/xarchiver/xarchiver-0.5.4.14.ebuild b/app-arch/xarchiver/xarchiver-0.5.4.14.ebuild
new file mode 100644
index 000000000000..12127f58d602
--- /dev/null
+++ b/app-arch/xarchiver/xarchiver-0.5.4.14.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools gnome2-utils xdg-utils
+
+DESCRIPTION="A GTK+ archive manager that can be used with Thunar"
+HOMEPAGE="https://github.com/ib/xarchiver"
+SRC_URI="https://github.com/ib/xarchiver/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+# older pigz versions have incompatible command-line processing
+# https://bugs.gentoo.org/661464
+RDEPEND=">=dev-libs/glib-2:=
+	x11-libs/gtk+:3=
+	!!<app-arch/pigz-2.4[symlink]"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/docbook-xml-dtd
+		app-text/docbook-xsl-stylesheets
+		dev-libs/libxml2
+		dev-libs/libxslt
+	)"
+
+src_prepare() {
+	sed -e '/COPYING/d' -e '/NEWS/d' -i doc/Makefile.am || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable doc)
+	)
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+
+	elog "You need external programs for some formats, including:"
+	elog "7zip - app-arch/p7zip"
+	elog "arj - app-arch/unarj app-arch/arj"
+	elog "lha - app-arch/lha"
+	elog "lzop - app-arch/lzop"
+	elog "rar - app-arch/unrar app-arch/rar"
+	elog "zip - app-arch/unzip app-arch/zip"
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
-- 
cgit v1.2.3-18-g5258