From f4237237343bf492a60130d7e2e84e8be2f4488f Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Sat, 2 Jul 2022 22:06:58 +0200
Subject: app-arch/pdv: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 app-arch/pdv/pdv-1.5.1-r3.ebuild | 60 ---------------------------------------
 app-arch/pdv/pdv-1.5.1-r4.ebuild | 61 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+), 60 deletions(-)
 delete mode 100644 app-arch/pdv/pdv-1.5.1-r3.ebuild
 create mode 100644 app-arch/pdv/pdv-1.5.1-r4.ebuild

(limited to 'app-arch')

diff --git a/app-arch/pdv/pdv-1.5.1-r3.ebuild b/app-arch/pdv/pdv-1.5.1-r3.ebuild
deleted file mode 100644
index 8b712196c4de..000000000000
--- a/app-arch/pdv/pdv-1.5.1-r3.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit autotools toolchain-funcs
-
-DESCRIPTION="build a self-extracting and self-installing binary package"
-HOMEPAGE="https://sourceforge.net/projects/pdv"
-SRC_URI="mirror://sourceforge/pdv/${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 ~hppa ppc x86 ~x86-linux ~ppc-macos"
-IUSE="X"
-
-DEPEND="
-	X? (
-		>=x11-libs/motif-2.3:0
-		>=x11-libs/libX11-1.0.0
-		>=x11-libs/libXt-1.0.0
-		>=x11-libs/libXext-1.0.0 )
-"
-RDEPEND="${DEPEND}"
-
-src_prepare() {
-	default
-
-	# fix a size-of-variable bug
-	eapply "${FILESDIR}"/${P}-opt.patch
-	# fix a free-before-use bug
-	eapply "${FILESDIR}"/${P}-early-free.patch
-	# fix a configure script bug
-	eapply "${FILESDIR}"/${P}-x-config.patch
-	# fix default args bug from assuming 'char' is signed
-	eapply "${FILESDIR}"/${P}-default-args.patch
-	# prevent pre-stripped binaries
-	eapply "${FILESDIR}"/${P}-no-strip.patch
-
-	# re-build configure script since patch was applied to configure.in
-	cd "${S}"/X11
-	mv configure.in configure.ac || die
-	eautoreconf
-	tc-export CC
-}
-
-src_configure() {
-	local myconf=""
-	use X || myconf="--without-x" # configure script is broken, cant use use_with
-	econf ${myconf}
-}
-
-src_install() {
-	dobin pdv pdvmkpkg
-	doman pdv.1 pdvmkpkg.1
-	if use X ; then
-		dobin X11/xmpdvmkpkg
-		doman xmpdvmkpkg.1
-	fi
-	dodoc AUTHORS ChangeLog NEWS README pdv.lsm
-}
diff --git a/app-arch/pdv/pdv-1.5.1-r4.ebuild b/app-arch/pdv/pdv-1.5.1-r4.ebuild
new file mode 100644
index 000000000000..b50f939fa91a
--- /dev/null
+++ b/app-arch/pdv/pdv-1.5.1-r4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="build a self-extracting and self-installing binary package"
+HOMEPAGE="https://sourceforge.net/projects/pdv"
+SRC_URI="mirror://sourceforge/pdv/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 ~hppa ppc x86 ~x86-linux ~ppc-macos"
+IUSE="gui"
+
+RDEPEND="
+	gui? (
+		>=x11-libs/motif-2.3:0
+		>=x11-libs/libX11-1.0.0
+		>=x11-libs/libXt-1.0.0
+		>=x11-libs/libXext-1.0.0
+	)"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	# fix a size-of-variable bug
+	"${FILESDIR}"/${P}-opt.patch
+	# fix a free-before-use bug
+	"${FILESDIR}"/${P}-early-free.patch
+	# fix a configure script bug
+	"${FILESDIR}"/${P}-x-config.patch
+	# fix default args bug from assuming 'char' is signed
+	"${FILESDIR}"/${P}-default-args.patch
+	# prevent pre-stripped binaries
+	"${FILESDIR}"/${P}-no-strip.patch
+)
+
+src_prepare() {
+	default
+
+	# re-build configure script since patch was applied to configure.in
+	cd X11 || die
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	econf $(usev !gui --without-x) # configure script is broken, cant use use_with
+}
+
+src_install() {
+	dobin pdv pdvmkpkg
+	doman pdv.1 pdvmkpkg.1
+	if use gui ; then
+		dobin X11/xmpdvmkpkg
+		doman xmpdvmkpkg.1
+	fi
+	dodoc AUTHORS ChangeLog NEWS README pdv.lsm
+}
-- 
cgit v1.2.3-65-gdbad