From 458be8e9173787daf7fa5ee8226a672289c9c27e Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Tue, 26 Jul 2022 21:27:14 +0200
Subject: app-cdr/uif2iso: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 app-cdr/uif2iso/uif2iso-0.1.7c-r1.ebuild | 42 -----------------------------
 app-cdr/uif2iso/uif2iso-0.1.7c-r2.ebuild | 45 ++++++++++++++++++++++++++++++++
 2 files changed, 45 insertions(+), 42 deletions(-)
 delete mode 100644 app-cdr/uif2iso/uif2iso-0.1.7c-r1.ebuild
 create mode 100644 app-cdr/uif2iso/uif2iso-0.1.7c-r2.ebuild

(limited to 'app-cdr/uif2iso')

diff --git a/app-cdr/uif2iso/uif2iso-0.1.7c-r1.ebuild b/app-cdr/uif2iso/uif2iso-0.1.7c-r1.ebuild
deleted file mode 100644
index 5c029a5a00fb..000000000000
--- a/app-cdr/uif2iso/uif2iso-0.1.7c-r1.ebuild
+++ /dev/null
@@ -1,42 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="6"
-inherit toolchain-funcs
-
-DESCRIPTION="Convert CD images from uif (MagicISO) to iso"
-HOMEPAGE="http://aluigi.altervista.org/mytoolz.htm#uif2iso"
-SRC_URI="mirror://gentoo/${P}.zip
-	 test? ( https://yegortimoshenko.s3.amazonaws.com/${PN}-test.iso
-	       	 https://yegortimoshenko.s3.amazonaws.com/${PN}-test.uif )"
-
-LICENSE="GPL-2+"
-SLOT="0"
-KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux ~x64-macos"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="sys-libs/zlib"
-DEPEND="${RDEPEND}
-	app-arch/unzip"
-
-S="${WORKDIR}"
-
-src_compile() {
-	emake CC="$(tc-getCC)" -C src -f - <<-'EOF'
-	      CPPFLAGS += -DMAGICISO_IS_SHIT
-	      LDLIBS = -lz
-	      uif2iso: $(patsubst %.c,%.o,$(wildcard *.c))
-	EOF
-}
-
-src_test() {
-	einfo "checking that uif -> iso matches the expected output"
-	src/${PN} "${DISTDIR}/${PN}-test.uif" "${T}/${PN}-test.iso" # always returns 1
-	diff "${DISTDIR}/${PN}-test.iso" "${T}/${PN}-test.iso" || die "unexpected iso"
-}
-
-src_install() {
-	dobin src/${PN}
-	dodoc ${PN}.txt README
-}
diff --git a/app-cdr/uif2iso/uif2iso-0.1.7c-r2.ebuild b/app-cdr/uif2iso/uif2iso-0.1.7c-r2.ebuild
new file mode 100644
index 000000000000..ae20184cc167
--- /dev/null
+++ b/app-cdr/uif2iso/uif2iso-0.1.7c-r2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Convert CD images from uif (MagicISO) to iso"
+HOMEPAGE="http://aluigi.altervista.org/mytoolz.htm#uif2iso"
+SRC_URI="
+	mirror://gentoo/${P}.zip
+	test? (
+		https://yegortimoshenko.s3.amazonaws.com/${PN}-test.iso
+		https://yegortimoshenko.s3.amazonaws.com/${PN}-test.uif
+	)"
+S="${WORKDIR}"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/zlib"
+DEPEND="${RDEPEND}"
+BDEPEND="app-arch/unzip"
+
+src_compile() {
+	emake CC="$(tc-getCC)" -C src -f - <<- 'EOF'
+		CPPFLAGS += -DMAGICISO_IS_SHIT
+		LDLIBS = -lz
+		uif2iso: $(patsubst %.c,%.o,$(wildcard *.c))
+	EOF
+}
+
+src_test() {
+	einfo "checking that uif -> iso matches the expected output"
+	src/uif2iso "${DISTDIR}"/uif2iso-test.uif "${T}"/uif2iso-test.iso # always returns 1
+	diff "${DISTDIR}"/uif2iso-test.iso "${T}"/uif2iso-test.iso || die "unexpected iso"
+}
+
+src_install() {
+	dobin src/uif2iso
+	dodoc uif2iso.txt README
+}
-- 
cgit v1.2.3-65-gdbad