From 8d268bb82a07648c7c20586cab0d8ed5003301a3 Mon Sep 17 00:00:00 2001
From: Matthew Thode <prometheanfire@gentoo.org>
Date: Wed, 7 Oct 2020 10:09:02 -0500
Subject: app-crypt/acme: 1.9.0 bump

Package-Manager: Portage-3.0.4, Repoman-3.0.1
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>
---
 app-crypt/acme/acme-1.9.0.ebuild | 69 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 app-crypt/acme/acme-1.9.0.ebuild

(limited to 'app-crypt/acme/acme-1.9.0.ebuild')

diff --git a/app-crypt/acme/acme-1.9.0.ebuild b/app-crypt/acme/acme-1.9.0.ebuild
new file mode 100644
index 000000000000..9c58fbb71ad7
--- /dev/null
+++ b/app-crypt/acme/acme-1.9.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=(python{3_6,3_7,3_8})
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
+	inherit git-r3
+	S=${WORKDIR}/${P}/${PN}
+else
+	SRC_URI="https://github.com/certbot/certbot/archive/v${PV}.tar.gz -> certbot-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+	S=${WORKDIR}/certbot-${PV}/acme
+fi
+
+inherit distutils-r1
+
+DESCRIPTION="An implementation of the ACME protocol"
+HOMEPAGE="https://github.com/certbot/certbot https://letsencrypt.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/cryptography-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/josepy-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.15.1[${PYTHON_USEDEP}]
+	dev-python/pyrfc3339[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.10[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+	distutils-r1_src_compile
+	if use doc ; then
+		cd docs || die
+		sphinx-build -b html -d _build/doctrees   . _build/html
+	fi
+}
+
+python_test() {
+	nosetests -w ${PN} || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad