From 756605e0b1e143a14c53f6cc4db9f87f42bec734 Mon Sep 17 00:00:00 2001
From: Louis Sautier <sbraz@gentoo.org>
Date: Wed, 11 Aug 2021 13:34:48 +0200
Subject: app-crypt/acme: enable py3.10, fix tests and more

* Tests were not actually run by nose, switch to pytest instead, use the
  standard distutils_enable_tests function.
* Remove pytest-xdist from test dependencies as it is not required.
* Use distutils_enable_sphinx instead of complex phase function
  overrides.
* Remove idna from RDEPEND, it is not a direct dependency.

Signed-off-by: Louis Sautier <sbraz@gentoo.org>
---
 app-crypt/acme/acme-1.18.0-r1.ebuild | 39 ++++++++++++++++++++
 app-crypt/acme/acme-1.18.0.ebuild    | 69 ------------------------------------
 2 files changed, 39 insertions(+), 69 deletions(-)
 create mode 100644 app-crypt/acme/acme-1.18.0-r1.ebuild
 delete mode 100644 app-crypt/acme/acme-1.18.0.ebuild

(limited to 'app-crypt')

diff --git a/app-crypt/acme/acme-1.18.0-r1.ebuild b/app-crypt/acme/acme-1.18.0-r1.ebuild
new file mode 100644
index 000000000000..7c666ebed1ff
--- /dev/null
+++ b/app-crypt/acme/acme-1.18.0-r1.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
+	inherit git-r3
+	S=${WORKDIR}/${P}/${PN}
+else
+	SRC_URI="https://github.com/certbot/certbot/archive/v${PV}.tar.gz -> certbot-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+	S=${WORKDIR}/certbot-${PV}/acme
+fi
+
+DESCRIPTION="An implementation of the ACME protocol"
+HOMEPAGE="https://github.com/certbot/certbot https://letsencrypt.org/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.1.4[${PYTHON_USEDEP}]
+	>=dev-python/josepy-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-17.3.0[${PYTHON_USEDEP}]
+	dev-python/pyrfc3339[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.3.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
diff --git a/app-crypt/acme/acme-1.18.0.ebuild b/app-crypt/acme/acme-1.18.0.ebuild
deleted file mode 100644
index 2addb06332fc..000000000000
--- a/app-crypt/acme/acme-1.18.0.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-PYTHON_COMPAT=(python{3_7,3_8,3_9})
-DISTUTILS_USE_SETUPTOOLS=rdepend
-
-if [[ ${PV} == 9999* ]]; then
-	EGIT_REPO_URI="https://github.com/certbot/certbot.git"
-	inherit git-r3
-	S=${WORKDIR}/${P}/${PN}
-else
-	SRC_URI="https://github.com/certbot/certbot/archive/v${PV}.tar.gz -> certbot-${PV}.tar.gz"
-	KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
-	S=${WORKDIR}/certbot-${PV}/acme
-fi
-
-inherit distutils-r1
-
-DESCRIPTION="An implementation of the ACME protocol"
-HOMEPAGE="https://github.com/certbot/certbot https://letsencrypt.org/"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-IUSE="doc test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/chardet[${PYTHON_USEDEP}]
-	>=dev-python/cryptography-2.1.4[${PYTHON_USEDEP}]
-	>=dev-python/idna-2.0.0[${PYTHON_USEDEP}]
-	>=dev-python/josepy-1.1.0[${PYTHON_USEDEP}]
-	>=dev-python/pyopenssl-17.3.0[${PYTHON_USEDEP}]
-	dev-python/pyrfc3339[${PYTHON_USEDEP}]
-	dev-python/pytz[${PYTHON_USEDEP}]
-	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
-	>=dev-python/requests-toolbelt-0.3.0[${PYTHON_USEDEP}]
-"
-DEPEND="
-	doc? (
-		dev-python/sphinx[${PYTHON_USEDEP}]
-		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
-	)
-	test? (
-		${RDEPEND}
-		dev-python/nose[${PYTHON_USEDEP}]
-		dev-python/pytest[${PYTHON_USEDEP}]
-		dev-python/pytest-xdist[${PYTHON_USEDEP}]
-	)
-"
-
-src_compile() {
-	python_foreach_impl run_in_build_dir default
-	distutils-r1_src_compile
-	if use doc ; then
-		cd docs || die
-		sphinx-build -b html -d _build/doctrees   . _build/html
-	fi
-}
-
-python_test() {
-	nosetests -w ${PN} || die
-}
-
-python_install_all() {
-	use doc && local HTML_DOCS=( docs/_build/html/. )
-
-	distutils-r1_python_install_all
-}
-- 
cgit v1.2.3-65-gdbad