From b743a2a860090e3424970a2ec27245f58ba22602 Mon Sep 17 00:00:00 2001
From: Maciej Barć <xgqt@gentoo.org>
Date: Tue, 9 Apr 2024 10:21:18 +0200
Subject: app-emacs/dap-mode: bump to 0.8
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 app-emacs/dap-mode/dap-mode-0.8.ebuild | 65 ++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 app-emacs/dap-mode/dap-mode-0.8.ebuild

(limited to 'app-emacs/dap-mode/dap-mode-0.8.ebuild')

diff --git a/app-emacs/dap-mode/dap-mode-0.8.ebuild b/app-emacs/dap-mode/dap-mode-0.8.ebuild
new file mode 100644
index 000000000000..9131842d9a8a
--- /dev/null
+++ b/app-emacs/dap-mode/dap-mode-0.8.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=27.1
+
+inherit elisp
+
+DESCRIPTION="Debug Adapter Protocol mode"
+HOMEPAGE="https://github.com/emacs-lsp/dap-mode/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/emacs-lsp/${PN}"
+else
+	SRC_URI="https://github.com/emacs-lsp/${PN}/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-emacs/bui
+	app-emacs/dash
+	app-emacs/f
+	app-emacs/ht
+	app-emacs/hydra
+	app-emacs/lsp-docker
+	app-emacs/lsp-mode
+	app-emacs/lsp-treemacs
+	app-emacs/posframe
+	app-emacs/s
+"
+BDEPEND="
+	${RDEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-dap-ui-images-root-dir.patch"
+)
+
+DOCS=( CHANGELOG.org README.org )
+SITEFILE="50${PN}-gentoo.el"
+
+elisp-enable-tests ert-runner test
+
+src_prepare() {
+	elisp_src_prepare
+
+	sed "s|@SITEETC@|${SITEETC}/${PN}|" -i dap-ui.el || die
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto "${SITEETC}/${PN}"
+	doins -r icons
+}
-- 
cgit v1.2.3-65-gdbad