From 013cd6ea1cda74d6347ef60a2bd03c73f3bd56a9 Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Thu, 25 Feb 2021 18:38:26 +0100
Subject: app-emacs/emacs-common-gentoo: Version bump to 1.7
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Package-Manager: Portage-3.0.15, Repoman-3.0.2
Signed-off-by: Ulrich Müller <ulm@gentoo.org>
---
 app-emacs/emacs-common-gentoo/Manifest             |   1 +
 .../emacs-common-gentoo-1.7.ebuild                 | 103 +++++++++++++++++++++
 2 files changed, 104 insertions(+)
 create mode 100644 app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.7.ebuild

(limited to 'app-emacs/emacs-common-gentoo')

diff --git a/app-emacs/emacs-common-gentoo/Manifest b/app-emacs/emacs-common-gentoo/Manifest
index fd7d7bba1a0f..594dffa67791 100644
--- a/app-emacs/emacs-common-gentoo/Manifest
+++ b/app-emacs/emacs-common-gentoo/Manifest
@@ -1 +1,2 @@
 DIST emacs-common-gentoo-1.6.tar.xz 61224 BLAKE2B 70e4f30c26c9098fdb02a53cab5d60cb611143d8bac6947707f3c7596b5a81ceb513b5a0809ee90f351472824f1d4216720c02cadb51d25b3dfce5e436e02bdf SHA512 a7daed2241d778ab283482ecc016801e25084eed10fcbbc50e187d5f842df5a0d278a77f94ae950b086c8651e8ca1a18f89c11dffdde9cf9168755288aae926a
+DIST emacs-common-gentoo-1.7.tar.xz 61344 BLAKE2B bb5ec108ce230cfd45fa9cff1426b3731baf6a25b8346681128b0fc149649db5ca3b22720b3f8dba8495544f1ec5357a612aa35c687e36f5a181b2ab2fc324e5 SHA512 6c321a63d5329fe5e33f674951f1483acd724072a1d453ac0f4dbcb9b87825b735ac865fd9b9706a460b88828d1bfefbd65cc83d24a87b6359dd354c686605ce
diff --git a/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.7.ebuild b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.7.ebuild
new file mode 100644
index 000000000000..314ea5c739ad
--- /dev/null
+++ b/app-emacs/emacs-common-gentoo/emacs-common-gentoo-1.7.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit elisp-common desktop xdg-utils readme.gentoo-r1
+
+DESCRIPTION="Common files needed by all GNU Emacs versions"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
+SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
+IUSE="games gui"
+
+RDEPEND="games? ( acct-group/gamestat )"
+DEPEND="${RDEPEND}"
+PDEPEND=">=app-editors/emacs-23.1:*"
+
+src_install() {
+	insinto "${SITELISP}"
+	sed -e "s:@libdir@:$(get_libdir):g" subdirs.el.in | newins - subdirs.el
+	assert
+	newins site-gentoo.el{,.orig}
+
+	keepdir /etc/emacs
+	insinto /etc/emacs
+	doins site-start.el
+
+	if use games; then
+		keepdir /var/games/emacs
+		fowners 0:gamestat /var/games/emacs
+		fperms g+w /var/games/emacs
+	fi
+
+	if use gui; then
+		local i
+		domenu emacs.desktop emacsclient.desktop
+
+		pushd icons || die
+		newicon sink.png emacs-sink.png
+		newicon emacs25_48.png emacs.png
+		for i in 16 24 32 48 128; do
+			[[ ${i} -le 48 ]] && newicon -s ${i} emacs22_${i}.png emacs22.png
+			newicon -s ${i} emacs23_${i}.png emacs23.png
+			newicon -s ${i} emacs25_${i}.png emacs.png
+		done
+		doicon -s scalable emacs23.svg
+		newicon -s scalable emacs25.svg emacs.svg
+		popd
+	fi
+
+	DOC_CONTENTS="All site initialisation for Gentoo-installed packages is
+		added to ${SITELISP}/site-gentoo.el. In order for this site
+		initialisation to be loaded for all users automatically, a default
+		site startup file /etc/emacs/site-start.el is installed. You are
+		responsible for maintenance of this file.
+		\n\nAlternatively, individual users can add the following command:
+		\n\n(require 'site-gentoo)
+		\n\nto their ~/.emacs initialisation files, or, for greater
+		flexibility, users may load single package-specific initialisation
+		files from the ${SITELISP}/site-gentoo.d/ directory."
+	readme.gentoo_create_doc
+}
+
+pkg_preinst() {
+	# make sure that site-gentoo.el exists since site-start.el requires it
+	if [[ ! -f ${ED}${SITELISP}/site-gentoo.el ]]; then		#554518
+		mv "${ED}${SITELISP}"/site-gentoo.el{.orig,} || die
+	fi
+	if [[ -d ${EROOT}${SITELISP} ]]; then
+		elisp-site-regen
+		cp "${EROOT}${SITELISP}/site-gentoo.el" "${ED}${SITELISP}/" || die
+	fi
+
+	if use games; then
+		local f
+		for f in /var/games/emacs/{snake,tetris}-scores; do
+			if [[ -e ${EROOT}${f} ]]; then
+				cp "${EROOT}${f}" "${ED}${f}" || die
+			fi
+			touch "${ED}${f}" || die
+			chgrp gamestat "${ED}${f}" || die
+			chmod g+w "${ED}${f}" || die
+		done
+	fi
+}
+
+pkg_postinst() {
+	if use gui; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	if use gui; then
+		xdg_desktop_database_update
+		xdg_icon_cache_update
+	fi
+}
-- 
cgit v1.2.3-65-gdbad