From cb0ddafdc0d3e37d63e117408499412cf054c8db Mon Sep 17 00:00:00 2001
From: Jonathan Davies <jpds@protonmail.com>
Date: Sun, 27 Sep 2020 18:12:48 +0000
Subject: app-emulation/virt-manager: Version updated to 3.1.0 with changes:

* Set rdepend on argcomplete.
* Replaced perl dependency with docutils.

Bug: https://bugs.gentoo.org/713070
Signed-off-by: Jonathan Davies <jpds@protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/17694
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>
---
 app-emulation/virt-manager/Manifest                |  1 +
 .../virt-manager/virt-manager-3.1.0.ebuild         | 99 ++++++++++++++++++++++
 .../virt-manager/virt-manager-9999.ebuild          |  4 +-
 3 files changed, 102 insertions(+), 2 deletions(-)
 create mode 100644 app-emulation/virt-manager/virt-manager-3.1.0.ebuild

(limited to 'app-emulation/virt-manager')

diff --git a/app-emulation/virt-manager/Manifest b/app-emulation/virt-manager/Manifest
index 455f05287f0e..e8e1eea7b699 100644
--- a/app-emulation/virt-manager/Manifest
+++ b/app-emulation/virt-manager/Manifest
@@ -1 +1,2 @@
 DIST virt-manager-2.2.1.tar.gz 2623754 BLAKE2B c81e730f2d685152bd0ef0a0327a74a70c50bff91e80ed0e3de92d0b848183c4bc092be333f2f0785c6a0b39f0b6d6abbd1f38c902f52ba4af7c56d64ee9b026 SHA512 aa97af52b3552c087beab8701762c21e8e6d818c9787d5376ed4e1ae40a34d5e8870c4c00fda9cb17a2340d1dff5b17e853182df720cdd9ea4c91cf01502a33a
+DIST virt-manager-3.1.0.tar.gz 2848420 BLAKE2B 729a16ee419cfc9f118e4a59336e961f17f38908ab3aaa3598c83bff3e8bca75b150f0f38b021c5ccb839a7c43e87f071859f68c2a81425715e236e14d0a7929 SHA512 185e34d8ebb2f9755bf9732bdafdbe9d0924d8c3b69758947252cce5deeac2042f473ba63673eea2bf36beb1f216a856938650f86e2c86eb5618e8f8522df53d
diff --git a/app-emulation/virt-manager/virt-manager-3.1.0.ebuild b/app-emulation/virt-manager/virt-manager-3.1.0.ebuild
new file mode 100644
index 000000000000..cb575dc4df60
--- /dev/null
+++ b/app-emulation/virt-manager/virt-manager-3.1.0.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_SINGLE_IMPL=1
+
+DISTUTILS_USE_SETUPTOOLS=no
+inherit gnome2 distutils-r1
+
+DESCRIPTION="A graphical tool for administering virtual machines"
+HOMEPAGE="http://virt-manager.org"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	SRC_URI=""
+	KEYWORDS="amd64 arm64 x86"
+	EGIT_REPO_URI="https://github.com/virt-manager/virt-manager.git"
+else
+	SRC_URI="http://virt-manager.org/download/sources/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gtk policykit sasl"
+
+RDEPEND="!app-emulation/virtinst
+	${PYTHON_DEPS}
+	app-cdr/cdrtools
+	>=app-emulation/libvirt-glib-1.0.0[introspection]
+	$(python_gen_cond_dep '
+		dev-libs/libxml2[python,${PYTHON_MULTI_USEDEP}]
+		dev-python/argcomplete[${PYTHON_MULTI_USEDEP}]
+		dev-python/libvirt-python[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
+		dev-python/requests[${PYTHON_MULTI_USEDEP}]
+	')
+	>=sys-libs/libosinfo-0.2.10[introspection]
+	gtk? (
+		gnome-base/dconf
+		>=net-libs/gtk-vnc-0.3.8[gtk3(+),introspection]
+		net-misc/spice-gtk[usbredir,gtk3,introspection,sasl?]
+		net-misc/x11-ssh-askpass
+		x11-libs/gtk+:3[introspection]
+		x11-libs/gtksourceview:4[introspection]
+		x11-libs/vte:2.91[introspection]
+		policykit? ( sys-auth/polkit[introspection] )
+	)
+"
+DEPEND="${RDEPEND}
+	dev-python/docutils
+	dev-util/intltool
+"
+
+DOCS=( README.md NEWS.md )
+
+src_prepare() {
+	distutils-r1_src_prepare
+}
+
+python_configure() {
+	esetup.py configure \
+		--default-graphics=spice
+}
+
+python_install() {
+	esetup.py install
+}
+
+src_install() {
+	local mydistutilsargs=( --no-update-icon-cache --no-compile-schemas )
+	distutils-r1_src_install
+
+	python_fix_shebang "${ED}"/usr/share/virt-manager
+}
+
+pkg_preinst() {
+	if use gtk; then
+		gnome2_pkg_preinst
+
+		cd "${ED}"
+		export GNOME2_ECLASS_ICONS=$(find 'usr/share/virt-manager/icons' -maxdepth 1 -mindepth 1 -type d 2> /dev/null)
+	else
+		rm -rf "${ED}/usr/share/virt-manager/virtManager"
+		rm -f "${ED}/usr/share/virt-manager/virt-manager"
+		rm -rf "${ED}/usr/share/virt-manager/ui/"
+		rm -rf "${ED}/usr/share/virt-manager/icons/"
+		rm -rf "${ED}/usr/share/man/man1/virt-manager.1*"
+		rm -rf "${ED}/usr/share/icons/"
+		rm -rf "${ED}/usr/share/applications/virt-manager.desktop"
+		rm -rf "${ED}/usr/bin/virt-manager"
+	fi
+}
+
+pkg_postinst() {
+	use gtk && gnome2_pkg_postinst
+}
diff --git a/app-emulation/virt-manager/virt-manager-9999.ebuild b/app-emulation/virt-manager/virt-manager-9999.ebuild
index dc329fa32f1f..a3390883c4d3 100644
--- a/app-emulation/virt-manager/virt-manager-9999.ebuild
+++ b/app-emulation/virt-manager/virt-manager-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=6
 
-PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_COMPAT=( python3_{7,8,9} )
 DISTUTILS_SINGLE_IMPL=1
 
 DISTUTILS_USE_SETUPTOOLS=no
@@ -50,7 +50,7 @@ RDEPEND="!app-emulation/virtinst
 	)
 "
 DEPEND="${RDEPEND}
-	dev-lang/perl
+	dev-python/docutils
 	dev-util/intltool
 "
 
-- 
cgit v1.2.3-65-gdbad