From 81b2fcc4ef99f828f27fc5d2621bd89f03ba6558 Mon Sep 17 00:00:00 2001
From: Maciej Barć <xgqt@gentoo.org>
Date: Sat, 21 Jan 2023 00:10:39 +0100
Subject: app-misc/golly: bump to 4.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Bug: https://bugs.gentoo.org/577030
Closes: https://bugs.gentoo.org/890330
Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 app-misc/golly/golly-4.2.ebuild | 70 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)
 create mode 100644 app-misc/golly/golly-4.2.ebuild

(limited to 'app-misc/golly/golly-4.2.ebuild')

diff --git a/app-misc/golly/golly-4.2.ebuild b/app-misc/golly/golly-4.2.ebuild
new file mode 100644
index 000000000000..2cdfc69578d6
--- /dev/null
+++ b/app-misc/golly/golly-4.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+WX_GTK_VER=3.2-gtk3
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit desktop python-single-r1 toolchain-funcs wxwidgets xdg
+
+DESCRIPTION="simulator for Conway's Game of Life and other cellular automata"
+HOMEPAGE="http://golly.sourceforge.net/
+	https://sourceforge.net/projects/golly/"
+SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"
+S="${WORKDIR}/${P}-src"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	sys-libs/zlib
+	virtual/opengl
+	x11-libs/wxGTK:${WX_GTK_VER}[X,curl,opengl,sdl,tiff]
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}"/${PN}-4.0-CFLAGS.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	setup-wxwidgets
+}
+
+src_compile() {
+	local -a mymakeopts=(
+		ENABLE_SOUND=yes
+		GOLLYDIR="${EPREFIX}/usr/share/${PN}"
+		PYTHON=${EPYTHON}
+		WX_CONFIG=${WX_CONFIG}
+		AR="$(tc-getAR)"
+		CC="$(tc-getCC)"
+		CXX="$(tc-getCXX)"
+		CXXC="$(tc-getCXX)"
+		RANLIB="$(tc-getRANLIB)"
+	)
+	emake -C gui-wx -f makefile-gtk "${mymakeopts[@]}"
+}
+
+src_install() {
+	# Has no 'make install', let's install files manually.
+	exeinto /usr/bin
+	doexe golly bgolly
+
+	insinto /usr/share/${PN}
+	doins -r Help Patterns Scripts Rules docs
+
+	newicon --size 32 gui-wx/icons/appicon.xpm ${PN}.xpm
+	make_desktop_entry ${PN} "Golly" ${PN} "Science"
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
-- 
cgit v1.2.3-65-gdbad