From d7cdb079e19b19de0e56a30eb0de9b7bc3055fb4 Mon Sep 17 00:00:00 2001
From: Patrick McLean <chutzpah@gentoo.org>
Date: Thu, 2 Dec 2021 17:46:58 -0800
Subject: app-misc/yq: Version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 app-misc/yq/yq-2.13.0.ebuild | 48 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 app-misc/yq/yq-2.13.0.ebuild

(limited to 'app-misc/yq/yq-2.13.0.ebuild')

diff --git a/app-misc/yq/yq-2.13.0.ebuild b/app-misc/yq/yq-2.13.0.ebuild
new file mode 100644
index 000000000000..43c89f52a700
--- /dev/null
+++ b/app-misc/yq/yq-2.13.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{7..10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Command-line YAML processor - jq wrapper for YAML documents"
+HOMEPAGE="https://yq.readthedocs.io/ https://github.com/kislyuk/yq/ https://pypi.org/project/yq/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-misc/jq
+	dev-python/argcomplete[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/yq-2.13.0-tests.patch"
+)
+
+python_prepare_all() {
+	sed -e 's:unittest.main():unittest.main(verbosity=2):' \
+		-i test/test.py || die
+
+	sed -r -i 's:[[:space:]]*"coverage",:: ; s:[[:space:]]*"flake8",::' \
+		setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" test/test.py </dev/null || die "tests failed under ${EPYTHON}"
+}
-- 
cgit v1.2.3-65-gdbad