From e64592dad2e22cc58b5c19ac5d2b2c180c12f1fc Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Wed, 20 Mar 2019 14:02:11 +0100
Subject: app-text/xchm: Version 1.27

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 app-text/xchm/xchm-1.27.ebuild | 52 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 app-text/xchm/xchm-1.27.ebuild

(limited to 'app-text/xchm/xchm-1.27.ebuild')

diff --git a/app-text/xchm/xchm-1.27.ebuild b/app-text/xchm/xchm-1.27.ebuild
new file mode 100644
index 000000000000..a2c546cdaf3c
--- /dev/null
+++ b/app-text/xchm/xchm-1.27.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER="3.0-gtk3"
+
+inherit wxwidgets xdg-utils
+
+DESCRIPTION="Utility for viewing Compiled HTML Help (CHM) files"
+HOMEPAGE="https://github.com/rzvncj/xCHM/"
+SRC_URI="${HOMEPAGE}releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+DEPEND="
+	>=dev-libs/chmlib-0.36
+	x11-libs/wxGTK:${WX_GTK_VER}[X]
+"
+RDEPEND="
+	${DEPEND}
+"
+
+src_prepare() {
+	setup-wxwidgets
+	default
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS README ChangeLog
+
+	cp "${D}"/usr/share/pixmaps/xchm-32.xpm "${D}"/usr/share/pixmaps/xchm.xpm
+	rm -f "${D}"/usr/share/pixmaps/xchm-*.xpm
+	rm -f "${D}"/usr/share/pixmaps/xchmdoc*.xpm
+
+	domenu "${FILESDIR}"/xchm.desktop
+	insinto /usr/share/mime/packages
+	doins "${FILESDIR}"/xchm.xml
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
-- 
cgit v1.2.3-65-gdbad