From b4216e8a2dbd9ecb2a429ab9fd6fbdb7d240b7a4 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Sat, 7 Sep 2019 13:58:14 +0300
Subject: dev-cpp/glibmm: bump to 2.60.0

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 dev-cpp/glibmm/glibmm-2.60.0.ebuild | 65 +++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 dev-cpp/glibmm/glibmm-2.60.0.ebuild

(limited to 'dev-cpp/glibmm/glibmm-2.60.0.ebuild')

diff --git a/dev-cpp/glibmm/glibmm-2.60.0.ebuild b/dev-cpp/glibmm/glibmm-2.60.0.ebuild
new file mode 100644
index 000000000000..1f41a3b2f177
--- /dev/null
+++ b/dev-cpp/glibmm/glibmm-2.60.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2 multilib-minimal
+
+DESCRIPTION="C++ interface for glib2"
+HOMEPAGE="https://www.gtkmm.org"
+
+LICENSE="LGPL-2.1+ GPL-2+" # GPL-2+ applies only to the build system
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="doc debug test"
+
+RDEPEND="
+	>=dev-libs/libsigc++-2.9.1:2[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.59.2:2[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+# dev-cpp/mm-common needed for eautoreconf
+
+src_prepare() {
+	if ! use test; then
+		# don't waste time building tests
+		sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' \
+			-i Makefile.am Makefile.in || die "sed 1 failed"
+	fi
+
+	# don't build examples - we want to install example sources, not binaries
+	sed 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' \
+		-i Makefile.am Makefile.in || die "sed 2 failed"
+
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" gnome2_src_configure \
+		$(use_enable debug debug-refcounting) \
+		$(multilib_native_use_enable doc documentation) \
+		--enable-deprecated-api
+}
+
+multilib_src_test() {
+	cd tests
+	default
+
+	for i in */test; do
+		${i} || die "Running tests failed at ${i}"
+	done
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	find examples -type d -name '.deps' -exec rm -rf {} \; 2>/dev/null
+	find examples -type f -name 'Makefile*' -exec rm -f {} \; 2>/dev/null
+	dodoc -r examples
+}
-- 
cgit v1.2.3