From 9780fa2b000abf2843edd7bed686e5d4bcf35a6e Mon Sep 17 00:00:00 2001
From: "Volkmar W. Pogatzki" <gentoo@pogatzki.net>
Date: Thu, 22 Feb 2024 10:39:16 +0100
Subject: dev-java/junit: add 4.13.2_p20240222 to allow jdk:21
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Bug: https://bugs.gentoo.org/916398
Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
---
 dev-java/junit/junit-4.13.2_p20240222.ebuild | 53 ++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-java/junit/junit-4.13.2_p20240222.ebuild

(limited to 'dev-java/junit/junit-4.13.2_p20240222.ebuild')

diff --git a/dev-java/junit/junit-4.13.2_p20240222.ebuild b/dev-java/junit/junit-4.13.2_p20240222.ebuild
new file mode 100644
index 000000000000..3ca8e79546cc
--- /dev/null
+++ b/dev-java/junit/junit-4.13.2_p20240222.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+JAVA_PKG_IUSE="doc source test"
+MAVEN_ID="junit:junit:${PV}"
+
+inherit java-pkg-2 java-pkg-simple
+
+DESCRIPTION="Simple framework to write repeatable tests"
+HOMEPAGE="https://junit.org/junit4/"
+MY_COMMIT="28fa2cae48b365c949935b28967ffb3f388e77ef"
+SRC_URI="https://github.com/${PN}-team/${PN}4/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}4-${MY_COMMIT}"
+
+LICENSE="EPL-1.0"
+SLOT="4"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+
+CP_DEPEND="dev-java/hamcrest-core:1.3"
+DEPEND="${CP_DEPEND}
+	>=virtual/jdk-1.8:*
+	test? ( dev-java/hamcrest-library:1.3 )"
+RDEPEND="${CP_DEPEND}
+	>=virtual/jre-1.8:*"
+
+PATCHES=( "${FILESDIR}/junit-4.13.2_p20240222-ignore-failing-test.patch" )
+
+JAVA_AUTOMATIC_MODULE_NAME="junit"
+JAVA_ENCODING="ISO-8859-1"
+JAVA_RESOURCE_DIRS="src/main/resources"
+JAVA_SRC_DIR="src/main/java"
+
+JAVA_TEST_GENTOO_CLASSPATH="hamcrest-core-1.3,hamcrest-library-1.3"
+JAVA_TEST_SRC_DIR="src/test/java"
+JAVA_TEST_RESOURCE_DIRS="src/test/resources"
+
+src_prepare() {
+	default #780585
+	java-pkg-2_src_prepare
+}
+
+src_test() {
+	cd "${JAVA_TEST_SRC_DIR}" || die
+
+	local CP=".:../resources:${S}/${PN}.jar:$(java-pkg_getjars ${JAVA_TEST_GENTOO_CLASSPATH})"
+
+	ejavac -cp "${CP}" -d . $(find * -name "*.java")
+	# pom.xml lines 264-268
+	java -cp "${CP}" -Djava.awt.headless=true \
+		org.junit.runner.JUnitCore org.junit.tests.AllTests || die "Running junit failed"
+}
-- 
cgit v1.2.3-65-gdbad