From b4154fabf40ed0574cbb52b5d771f03ee57902fa Mon Sep 17 00:00:00 2001
From: Austin English <wizardedit@gentoo.org>
Date: Mon, 18 Dec 2017 14:57:58 -0600
Subject: dev-lang/tcc: version bump, 0.9.27

---
 dev-lang/tcc/tcc-0.9.27.ebuild | 65 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 dev-lang/tcc/tcc-0.9.27.ebuild

(limited to 'dev-lang/tcc/tcc-0.9.27.ebuild')

diff --git a/dev-lang/tcc/tcc-0.9.27.ebuild b/dev-lang/tcc/tcc-0.9.27.ebuild
new file mode 100644
index 000000000000..9900cc9ea3a2
--- /dev/null
+++ b/dev-lang/tcc/tcc-0.9.27.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit toolchain-funcs
+
+DESCRIPTION="A very small C compiler for ix86/amd64"
+HOMEPAGE="http://bellard.org/tcc/"
+SRC_URI="http://download.savannah.gnu.org/releases/tinycc/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+
+DEPEND="dev-lang/perl" # doc generation
+# Both tendra and tinycc install /usr/bin/tcc
+RDEPEND="!dev-lang/tendra"
+IUSE="test"
+
+src_prepare() {
+	# Don't strip
+	sed -i -e 's|$(INSTALL) -s|$(INSTALL)|' Makefile || die
+
+	# Fix examples
+	sed -i -e '1{
+		i#! /usr/bin/tcc -run
+		/^#!/d
+	}' examples/ex*.c || die
+	sed -i -e '1s/$/ -lX11/' examples/ex4.c || die
+
+	# Fix texi2html invocation
+	sed -i -e 's/-number//' Makefile || die
+	sed -i -e 's/--sections//' Makefile || die
+
+	eapply_user
+}
+
+src_configure() {
+	use test && unset CFLAGS LDFLAGS # Tests run with CC=tcc etc, they will fail hard otherwise
+					# better fixes welcome, it feels wrong to hack the env like this
+	# not autotools, so call configure directly
+	./configure --cc="$(tc-getCC)" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}"
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc Changelog README TODO VERSION
+	#dohtml tcc-doc.html
+	exeinto /usr/share/doc/${PF}/examples
+	doexe examples/ex*.c
+}
+
+src_test() {
+	# this is using tcc bits that don't know as-needed etc.
+	TCCFLAGS="" emake test
+}
-- 
cgit v1.2.3-65-gdbad