From ba94f60952a5743f4ff2a3029c42fb7fdf8fd27f Mon Sep 17 00:00:00 2001
From: Mike Frysinger <vapier@chromium.org>
Date: Tue, 10 Jan 2023 14:16:48 -0500
Subject: dev-libs/confuse: enable LFS

Enable automatic LFS support for 32-bit ABIs.  This should be safe
as the library ABI doesn't use any FS-types (e.g. off_t or struct
stat), and internally the code doesn't interact with the FS much.

Upstream: https://github.com/libconfuse/libconfuse/pull/167
Signed-off-by: Mike Frysinger <vapier@gentoo.org>
---
 dev-libs/confuse/confuse-3.3-r1.ebuild | 56 ++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 dev-libs/confuse/confuse-3.3-r1.ebuild

(limited to 'dev-libs/confuse')

diff --git a/dev-libs/confuse/confuse-3.3-r1.ebuild b/dev-libs/confuse/confuse-3.3-r1.ebuild
new file mode 100644
index 000000000000..b248bf5d34f6
--- /dev/null
+++ b/dev-libs/confuse/confuse-3.3-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib-minimal flag-o-matic
+
+DESCRIPTION="a configuration file parser library"
+HOMEPAGE="https://github.com/martinh/libconfuse"
+SRC_URI="https://github.com/martinh/libconfuse/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0/2.1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+
+IUSE="nls static-libs"
+
+BDEPEND="
+	sys-devel/flex
+	sys-devel/libtool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="
+	nls? ( virtual/libintl[${MULTILIB_USEDEP}] )
+"
+
+DOCS=( AUTHORS )
+
+src_prepare() {
+	default
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	# https://github.com/libconfuse/libconfuse/pull/167
+	append-lfs-flags
+
+	# examples are normally compiled but not installed. They
+	# fail during a mingw crosscompile.
+	local ECONF_SOURCE=${BUILD_DIR}
+	econf \
+		--enable-shared \
+		--disable-examples \
+		$(use_enable nls) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+	doman doc/man/man3/*.3
+	dodoc -r doc/html
+
+	docinto examples
+	dodoc examples/*.{c,conf}
+
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad