From b536545a9446b985ffbb90d1cb9f8b15f8621f78 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Fri, 31 Jul 2020 13:11:07 +0200
Subject: dev-libs/libbytesize: Bump to version 2.4

Package-Manager: Portage-3.0.1, Repoman-2.3.23
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-libs/libbytesize/libbytesize-2.4.ebuild | 80 +++++++++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 dev-libs/libbytesize/libbytesize-2.4.ebuild

(limited to 'dev-libs/libbytesize/libbytesize-2.4.ebuild')

diff --git a/dev-libs/libbytesize/libbytesize-2.4.ebuild b/dev-libs/libbytesize/libbytesize-2.4.ebuild
new file mode 100644
index 000000000000..0d91bc5f9998
--- /dev/null
+++ b/dev-libs/libbytesize/libbytesize-2.4.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit python-r1
+
+DESCRIPTION="Tiny library providing a C \"class\" for working with arbitrary big sizes in bytes"
+HOMEPAGE="https://github.com/storaged-project/libbytesize"
+SRC_URI="https://github.com/storaged-project/libbytesize/releases/download/${PV}/${P}.tar.gz"
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc python test tools"
+
+REQUIRED_USE="
+	python? ( ${PYTHON_REQUIRED_USE} )
+	tools? ( python )
+"
+
+RDEPEND="
+	dev-libs/gmp:0=
+	dev-libs/mpfr:=
+	dev-libs/libpcre2
+	python? ( ${PYTHON_DEPS} )
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	sys-devel/gettext
+	doc? ( dev-util/gtk-doc )
+	test? (
+		dev-python/pocketlint[${PYTHON_USEDEP}]
+		dev-python/polib[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( README.md )
+
+RESTRICT="test"
+
+python_do() {
+	if use python; then
+		python_foreach_impl run_in_build_dir "$@"
+	else
+		"$@"
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with doc gtk-doc)
+		$(use_with python python3)
+		$(use_with tools)
+	)
+	local ECONF_SOURCE="${S}"
+	python_do econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	python_do emake
+}
+
+src_test() {
+	python_do emake check
+}
+
+install_helper() {
+	emake DESTDIR="${D}" install
+	use python && python_optimize
+}
+
+src_install() {
+	python_do install_helper
+	einstalldocs
+	find "${ED}" -name "*.la" -type f -delete || die
+}
-- 
cgit v1.2.3-65-gdbad