From 401ad843933dfd86d083bf23eba722551d514893 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Tue, 9 May 2017 08:31:30 +0200
Subject: dev-libs/libcdio-paranoia: Re-enable symbol versions, #616054

Re-enable ld symbol versioning that has been accidentally disabled
by default upstream, as a result of OSX compatibility fixing. This
restores the previous ABI and fixes breakage when upgrading.

Closes: https://github.com/gentoo/gentoo/pull/4582
---
 .../libcdio-paranoia-0.94_p1-r1.ebuild             | 68 ++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 dev-libs/libcdio-paranoia/libcdio-paranoia-0.94_p1-r1.ebuild

(limited to 'dev-libs/libcdio-paranoia/libcdio-paranoia-0.94_p1-r1.ebuild')

diff --git a/dev-libs/libcdio-paranoia/libcdio-paranoia-0.94_p1-r1.ebuild b/dev-libs/libcdio-paranoia/libcdio-paranoia-0.94_p1-r1.ebuild
new file mode 100644
index 000000000000..7075f83d7a6a
--- /dev/null
+++ b/dev-libs/libcdio-paranoia/libcdio-paranoia-0.94_p1-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+MY_P=${PN}-10.2+${PV/_p/+}
+
+inherit eutils autotools multilib-minimal flag-o-matic
+
+DESCRIPTION="an advanced CDDA reader with error correction"
+HOMEPAGE="https://www.gnu.org/software/libcdio/"
+SRC_URI="mirror://gnu/${PN%-*}/${MY_P}.tar.gz"
+
+# COPYING-GPL from cdparanoia says "2 or later"
+# COPYING-LGPL from cdparanoia says "2.1 or later" but 2 files are without the
+# clause "or later" so we use LGPL-2.1 without +
+LICENSE="GPL-3+ GPL-2+ LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="+cxx static-libs test"
+
+RDEPEND="app-eselect/eselect-cdparanoia
+	>=dev-libs/libcdio-0.94:0=[${MULTILIB_USEDEP}]
+	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r10
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-lang/perl )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( AUTHORS ChangeLog NEWS README.md THANKS )
+
+src_prepare() {
+	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:' configure.ac || die #466410
+	default
+	eautoreconf
+
+	[[ ${CC} == *clang* ]] && append-flags -std=gnu89
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-maintainer-mode
+		--disable-example-progs
+		$(use_enable cxx)
+		--disable-cpp-progs
+		--with-cd-paranoia-name=libcdio-paranoia
+		# upstream accidentally default-disabled it
+		# reenable it to preserve ABI compat with previous versions
+		# https://bugs.gentoo.org/616054
+		# https://savannah.gnu.org/bugs/index.php?50978
+		--enable-ld-version-script
+	)
+	# Darwin linker doesn't get this
+	[[ ${CHOST} == *-darwin* ]] && myeconfargs+=( --disable-ld-version-script )
+	ECONF_SOURCE="${S}" \
+	econf "${myeconfargs[@]}"
+}
+
+pkg_postinst() {
+	eselect cdparanoia update ifunset
+}
+
+pkg_postrm() {
+	eselect cdparanoia update ifunset
+}
-- 
cgit v1.2.3-18-g5258